# Contributor: Flamelab <panosfilip@gmail.com>
# Previous Contributor: vbmithr

pkgname=xf86-video-ati-git
_realpkgname=xf86-video-ati
pkgver=20090721
pkgrel=1
pkgdesc="X.org ati video driver"
arch=("i686" "x86_64")
url="http://xorg.freedesktop.org/"
_latestver=6.12.99
provides=("${_realpkgname}=${_latestver}")
depends=('libdrm-radeon-git' 'libpciaccess' 'ati-dri>=7.4.2')
makedepends=('pkgconfig' 'xorg-server>=1.6.1' 'mesa>=7.4' 'fontsproto' 'inputproto' 'ghostscript' 'automake' \
	     'glproto>=1.4.9' 'xf86driproto' 'diffutils' 'dri2proto' 'xorg-util-macros' 'git' 'autoconf')
conflicts=('xorg-server<1.6.0' 'xf86-video-ati')
options=('!libtool')
license=('custom')
source=('LICENSE')
md5sums=('75da66945980a43adf1e1856271b9d4a')

_gitroot="git://anongit.freedesktop.org/xorg/driver/xf86-video-ati"
_gitname="xf86-video-ati"

build() 

{ 
    cd ${srcdir}/

    msg "Connecting to the Freedesktop.org GIT server...."
    if [[ -d ${srcdir}/${_gitname} ]] ; then
    	cd ${_gitname}
    	git pull origin
    	msg "The local files are updated..."
    else
    	git clone ${_gitroot}
    fi
    
    msg "GIT checkout done."

    msg "Starting make for: ${pkgname}"
    
    if [[ -d ${srcdir}/${_gitname}-build ]]; then
       msg "Cleaning the previous build directory..." 
       rm -rf ${srcdir}/${_gitname}-build
    fi

    cp -r ${srcdir}/${_gitname} ${srcdir}/${_gitname}-build
    
    cd ${srcdir}/${_gitname}-build

    autoreconf -v --install || return 1  
    
    msg "Starting configure..."
    ./configure \
            --prefix=/usr \
            --enable-maintainer-mode \
            --enable-shave=no \
            --enable-dependency-tracking \
            --enable-exa \
            --enable-dri  || return 1
    
    msg "Starting make..."
    make || return 1
    make DESTDIR=${pkgdir} install || return 1
 
    msg "Copying license..."
    install -Dm644 ${srcdir}/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
     
    msg "Cleaning build directory..."
    rm -rf ${srcdir}/$_gitname-build
}