# Mesa for R600, hw_gl_select2-branch flavour. Arch Linux PKGBUILD for easy testing.
# Bugs: https://bugs.freedesktop.org/show_bug.cgi?id=34495
# Note: if it doesn't build, try downgrading bison to 2.7

pkgname=mesa-hw_gl_select2
pkgver=9.2.56903
pkgrel=1
_realver=9.2
pkgdesc="Mesa for R600, hw_gl_select2-branch flavour."
arch=('x86_64')
depends=('libxxf86vm' 'libxvmc' 'libxdamage' 'xorg-server' 'libvdpau' 'wayland' 'elfutils' 'llvm-libs')
makedepends=('pkgconfig' 'python2' 'talloc' 'libxml2' 'imake' 'git' 'glproto' 'dri2proto>=2.6' 'xorg-server-devel' 'resourceproto' 'llvm')
optdepends=('libtxc_dxtn: S3TC support'
            'mesa-demos: glxinfo and glxgears')
provides=("mesa=${_realver}" "ati-dri=${_realver}" "libgl=${_realver}" "mesa-libgl=${_realver}" "khrplatform-devel=${_realver}" "libegl=${_realver}" "libgbm=${_realver}" "libglapi=${_realver}" "libgles=${_realver}" "osmesa=${_realver}")
conflicts=('mesa' 'ati-dri' 'libgl' 'mesa-libgl' 'khrplatform-devel' 'libegl' 'libgbm' 'libglapi' 'libgles' 'osmesa')
url="http://mesa3d.sourceforge.net"
source=("${pkgname}::git://people.freedesktop.org/~ab/mesa#branch=hw_gl_select2")
md5sums=(SKIP)
options=(!libtool)

pkgver() {
  cd "${pkgname}"
    echo ${_realver}.$(git rev-list --count HEAD)
}

build() {
  cd "${pkgname}"
  CPPFLAGS="$CPPFLAGS -O2" ./autogen.sh --prefix=/usr \
    --sysconfdir=/etc \
    --with-dri-driverdir=/usr/lib/xorg/modules/dri \
    --with-gallium-drivers=r600,swrast \
    --with-dri-drivers="" \
    --with-llvm-shared-libs \
    --enable-gallium-llvm \
    --enable-egl \
    --enable-gallium-egl \
    --with-egl-platforms=x11,drm,wayland \
    --enable-shared-glapi \
    --enable-gbm \
    --enable-glx-tls \
    --enable-dri \
    --enable-glx \
    --enable-osmesa \
    --enable-gles1 \
    --enable-gles2 \
    --enable-texture-float \
    --enable-xa \
    --enable-vdpau \
    --enable-gallium-gbm \
    --enable-r600-llvm-compiler

  make
}

package() {
  cd "${pkgname}" 
  make DESTDIR="${pkgdir}" install
  mv ${pkgdir}/usr/lib/libGL.so.1.2.0   ${pkgdir}/usr/lib/mesa-libGL.so.1.2.0
  rm ${pkgdir}/usr/lib/libGL.so{,.1}
  install -m755 -d "${pkgdir}/usr/lib/xorg/modules/extensions"
  ln -s libglx.xorg "${pkgdir}/usr/lib/xorg/modules/extensions/libglx.so"
  ln -s mesa-libGL.so.1.2.0      ${pkgdir}/usr/lib/libGL.so
  ln -s mesa-libGL.so.1.2.0      ${pkgdir}/usr/lib/libGL.so.1
  ln -s mesa-libGL.so.1.2.0      ${pkgdir}/usr/lib/libGL.so.1.2.0
  find "$pkgdir" -type d -name .git -exec rm -r '{}' +
}