Attachment 125739 Details for Bug 88922 – [01] Use AX_CODE_COVERAGE for test-coverage statistics

[patch] [01] Use AX_CODE_COVERAGE for test-coverage statistics

0001-Use-AX_CODE_COVERAGE-for-test-coverage-statistics.patch (text/plain), 18.10 KB, created by Thomas Zimmermann on 2016-08-12 15:07:00 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Thomas Zimmermann

Created: 2016-08-12 15:07:00 UTC

Size: 18.10 KB

patch

obsolete

>From 599013b527b45addd62ba62d5477b69b427577dd Mon Sep 17 00:00:00 2001
>From: Thomas Zimmermann <tdz@users.sourceforge.net>
>Date: Fri, 12 Aug 2016 10:50:53 +0200
>Subject: Use AX_CODE_COVERAGE for test-coverage statistics
>
>DBus uses custom rules in it's Makefiles to implement test-coverage
>statistics.
>
>This patch implements test-coverage statistics with the autoconf macro
>AX_CODE_COVERAGE. The script automatically tests for tools (e.g., gcov,
>lcov), sets build variables and creates Makefile rules.
>
>Run 'configure' with '--enable-code-coverage' to enable support for
>test-coverage statistics. Run 'make check-code-coverage' to run the
>tests and generate the statistics.
>
>Signed-off-by: Thomas Zimmermann <tdz@users.sourceforge.net>
>---
> Makefile.am            |   3 +
> bus/Makefile.am        |  12 +++
> configure.ac           |  13 ++-
> dbus/Makefile.am       |   7 +-
> m4/ax_code_coverage.m4 | 273 +++++++++++++++++++++++++++++++++++++++++++++++++
> test/Makefile.am       |   9 +-
> 6 files changed, 313 insertions(+), 4 deletions(-)
> create mode 100644 m4/ax_code_coverage.m4
>
>diff --git a/Makefile.am b/Makefile.am
>index 756ab8b..c116890 100644
>--- a/Makefile.am
>+++ b/Makefile.am
>@@ -33,4 +33,7 @@ DISTCHECK_CONFIGURE_FLAGS = \
> 
> ACLOCAL_AMFLAGS = -I m4 ${ACLOCAL_FLAGS}
> 
>+# Add rules for code-coverage testing, as defined by AX_CODE_COVERAGE
>+@CODE_COVERAGE_RULES@
>+
> include tools/lcov.am
>diff --git a/bus/Makefile.am b/bus/Makefile.am
>index 90092b1..6bbeacd 100644
>--- a/bus/Makefile.am
>+++ b/bus/Makefile.am
>@@ -3,6 +3,7 @@ legacydbusdatadir=$(sysconfdir)/dbus-1
> dbus_daemon_execdir = $(DBUS_DAEMONDIR)
> 
> DBUS_BUS_LIBS = \
>+	$(CODE_COVERAGE_LDFLAGS) \
> 	$(XML_LIBS) \
> 	$(SELINUX_LIBS) \
> 	$(APPARMOR_LIBS) \
>@@ -12,12 +13,14 @@ DBUS_BUS_LIBS = \
> 	$(NULL)
> 
> DBUS_LAUNCHER_LIBS = \
>+	$(CODE_COVERAGE_LDFLAGS) \
> 	$(XML_LIBS) \
> 	$(THREAD_LIBS) \
> 	$(NETWORK_libs) \
> 	$(NULL)
> 
> AM_CPPFLAGS = \
>+	$(CODE_COVERAGE_CPPFLAGS) \
> 	-I$(top_srcdir) \
> 	$(DBUS_STATIC_BUILD_CPPFLAGS) \
> 	$(XML_CFLAGS) \
>@@ -29,6 +32,12 @@ AM_CPPFLAGS = \
> # if assertions are enabled, improve backtraces
> AM_LDFLAGS = @R_DYNAMIC_LDFLAG@
> 
>+AM_CFLAGS = \
>+	$(CODE_COVERAGE_CFLAGS)
>+
>+AM_CXXFLAGS = \
>+	$(CODE_COVERAGE_CXXFLAGS)
>+
> EFENCE=
> 
> CONFIG_IN_FILES=				\
>@@ -327,6 +336,9 @@ systemduserunit_DATA = \
> 	$(NULL)
> endif
> 
>+# Add rules for code-coverage testing, as defined by AX_CODE_COVERAGE
>+@CODE_COVERAGE_RULES@
>+
> #### Extra dist
> 
> EXTRA_DIST=$(CONFIG_IN_FILES) $(SCRIPT_IN_FILES)
>diff --git a/configure.ac b/configure.ac
>index 2aac82e..2b2a38b 100644
>--- a/configure.ac
>+++ b/configure.ac
>@@ -333,6 +333,14 @@ AH_BOTTOM([
> #  define DBUS_ENABLE_CHECKS 1
> #endif])
> 
>+# Test for code-coverage tools if --enable-code-coverage
>+AX_CODE_COVERAGE
>+
>+if test x$enable_code_coverage = xyes; then
>+     ## so that config.h changes when you toggle gcov support
>+     AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
>+fi
>+
> if test x$enable_compiler_coverage = xyes; then
>      ## so that config.h changes when you toggle gcov support
>      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
>@@ -1893,7 +1901,7 @@ echo "
> 
> echo "
>         Rebuilding generated files: ${USE_MAINTAINER_MODE}
>-        gcc coverage profiling:   ${enable_compiler_coverage}
>+        gcc coverage profiling:   ${enable_code_coverage}
>         Building embedded tests:  ${enable_embedded_tests}
>         Building modular tests:   ${enable_modular_tests}
>             - with GLib:          ${with_glib}
>@@ -1937,6 +1945,9 @@ fi
> if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
>         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
> fi
>+if test x$enable_code_coverage = xyes; then
>+        echo "NOTE: building with coverage profiling is definitely for developers only."
>+fi
> if test x$enable_compiler_coverage = xyes; then
>         echo "NOTE: building with coverage profiling is definitely for developers only."
> fi
>diff --git a/dbus/Makefile.am b/dbus/Makefile.am
>index 0152486..fe1168b 100644
>--- a/dbus/Makefile.am
>+++ b/dbus/Makefile.am
>@@ -2,6 +2,7 @@
> dbusdatadir=$(datadir)/dbus-1
> 
> AM_CPPFLAGS = \
>+	$(CODE_COVERAGE_CPPFLAGS) \
> 	-I$(top_builddir) \
> 	-I$(top_srcdir) \
> 	$(DBUS_STATIC_BUILD_CPPFLAGS) \
>@@ -13,7 +14,8 @@ AM_CPPFLAGS = \
> 	-DDBUS_SESSION_CONFIG_FILE=\""$(dbusdatadir)/session.conf"\" \
> 	$(NULL)
> 
>-AM_CFLAGS =
>+AM_CFLAGS = \
>+	$(CODE_COVERAGE_CFLAGS)
> 
> if HAVE_VISIBILITY
> if !DBUS_WIN
>@@ -327,6 +329,9 @@ test_dbus_SOURCES=				\
> 
> test_dbus_LDADD = libdbus-internal.la
> 
>+# Add rules for code-coverage testing, as defined by AX_CODE_COVERAGE
>+@CODE_COVERAGE_RULES@
>+
> ## mop up the gcov files
> clean-local:
> 	/bin/rm *.bb *.bbg *.da *.gcov .libs/*.da .libs/*.bbg || true
>diff --git a/m4/ax_code_coverage.m4 b/m4/ax_code_coverage.m4
>new file mode 100644
>index 0000000..6c985eb
>--- /dev/null
>+++ b/m4/ax_code_coverage.m4
>@@ -0,0 +1,273 @@
>+# ===========================================================================
>+#     http://www.gnu.org/software/autoconf-archive/ax_code_coverage.html
>+# ===========================================================================
>+#
>+# SYNOPSIS
>+#
>+#   AX_CODE_COVERAGE()
>+#
>+# DESCRIPTION
>+#
>+#   Defines CODE_COVERAGE_CPPFLAGS, CODE_COVERAGE_CFLAGS,
>+#   CODE_COVERAGE_CXXFLAGS and CODE_COVERAGE_LDFLAGS which should be
>+#   included in the CPPFLAGS, CFLAGS CXXFLAGS and LIBS/LDFLAGS variables of
>+#   every build target (program or library) which should be built with code
>+#   coverage support. Also defines CODE_COVERAGE_RULES which should be
>+#   substituted in your Makefile; and $enable_code_coverage which can be
>+#   used in subsequent configure output. CODE_COVERAGE_ENABLED is defined
>+#   and substituted, and corresponds to the value of the
>+#   --enable-code-coverage option, which defaults to being disabled.
>+#
>+#   Test also for gcov program and create GCOV variable that could be
>+#   substituted.
>+#
>+#   Note that all optimisation flags in CFLAGS must be disabled when code
>+#   coverage is enabled.
>+#
>+#   Usage example:
>+#
>+#   configure.ac:
>+#
>+#     AX_CODE_COVERAGE
>+#
>+#   Makefile.am:
>+#
>+#     @CODE_COVERAGE_RULES@
>+#     my_program_LIBS = ... $(CODE_COVERAGE_LDFLAGS) ...
>+#     my_program_CPPFLAGS = ... $(CODE_COVERAGE_CPPFLAGS) ...
>+#     my_program_CFLAGS = ... $(CODE_COVERAGE_CFLAGS) ...
>+#     my_program_CXXFLAGS = ... $(CODE_COVERAGE_CXXFLAGS) ...
>+#
>+#   This results in a "check-code-coverage" rule being added to any
>+#   Makefile.am which includes "@CODE_COVERAGE_RULES@" (assuming the module
>+#   has been configured with --enable-code-coverage). Running `make
>+#   check-code-coverage` in that directory will run the module's test suite
>+#   (`make check`) and build a code coverage report detailing the code which
>+#   was touched, then print the URI for the report.
>+#
>+#   This code was derived from Makefile.decl in GLib, originally licenced
>+#   under LGPLv2.1+.
>+#
>+# LICENSE
>+#
>+#   Copyright (c) 2012, 2016 Philip Withnall
>+#   Copyright (c) 2012 Xan Lopez
>+#   Copyright (c) 2012 Christian Persch
>+#   Copyright (c) 2012 Paolo Borelli
>+#   Copyright (c) 2012 Dan Winship
>+#   Copyright (c) 2015 Bastien ROUCARIES
>+#
>+#   This library is free software; you can redistribute it and/or modify it
>+#   under the terms of the GNU Lesser General Public License as published by
>+#   the Free Software Foundation; either version 2.1 of the License, or (at
>+#   your option) any later version.
>+#
>+#   This library is distributed in the hope that it will be useful, but
>+#   WITHOUT ANY WARRANTY; without even the implied warranty of
>+#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser
>+#   General Public License for more details.
>+#
>+#   You should have received a copy of the GNU Lesser General Public License
>+#   along with this program. If not, see <http://www.gnu.org/licenses/>.
>+
>+#serial 15
>+
>+AC_DEFUN([AX_CODE_COVERAGE],[
>+	dnl Check for --enable-code-coverage
>+	AC_REQUIRE([AC_PROG_SED])
>+
>+	# allow to override gcov location
>+	AC_ARG_WITH([gcov],
>+	  [AS_HELP_STRING([--with-gcov[=GCOV]], [use given GCOV for coverage (GCOV=gcov).])],
>+	  [_AX_CODE_COVERAGE_GCOV_PROG_WITH=$with_gcov],
>+	  [_AX_CODE_COVERAGE_GCOV_PROG_WITH=gcov])
>+
>+	AC_MSG_CHECKING([whether to build with code coverage support])
>+	AC_ARG_ENABLE([code-coverage],
>+	  AS_HELP_STRING([--enable-code-coverage],
>+	  [Whether to enable code coverage support]),,
>+	  enable_code_coverage=no)
>+
>+	AM_CONDITIONAL([CODE_COVERAGE_ENABLED], [test x$enable_code_coverage = xyes])
>+	AC_SUBST([CODE_COVERAGE_ENABLED], [$enable_code_coverage])
>+	AC_MSG_RESULT($enable_code_coverage)
>+
>+	AS_IF([ test "$enable_code_coverage" = "yes" ], [
>+		# check for gcov
>+		AC_CHECK_TOOL([GCOV],
>+		  [$_AX_CODE_COVERAGE_GCOV_PROG_WITH],
>+		  [:])
>+		AS_IF([test "X$GCOV" = "X:"],
>+		  [AC_MSG_ERROR([gcov is needed to do coverage])])
>+		AC_SUBST([GCOV])
>+
>+		dnl Check if gcc is being used
>+		AS_IF([ test "$GCC" = "no" ], [
>+			AC_MSG_ERROR([not compiling with gcc, which is required for gcov code coverage])
>+		])
>+
>+		# List of supported lcov versions.
>+		lcov_version_list="1.6 1.7 1.8 1.9 1.10 1.11 1.12"
>+
>+		AC_CHECK_PROG([LCOV], [lcov], [lcov])
>+		AC_CHECK_PROG([GENHTML], [genhtml], [genhtml])
>+
>+		AS_IF([ test "$LCOV" ], [
>+			AC_CACHE_CHECK([for lcov version], ax_cv_lcov_version, [
>+				ax_cv_lcov_version=invalid
>+				lcov_version=`$LCOV -v 2>/dev/null | $SED -e 's/^.* //'`
>+				for lcov_check_version in $lcov_version_list; do
>+					if test "$lcov_version" = "$lcov_check_version"; then
>+						ax_cv_lcov_version="$lcov_check_version (ok)"
>+					fi
>+				done
>+			])
>+		], [
>+			lcov_msg="To enable code coverage reporting you must have one of the following lcov versions installed: $lcov_version_list"
>+			AC_MSG_ERROR([$lcov_msg])
>+		])
>+
>+		case $ax_cv_lcov_version in
>+			""|invalid[)]
>+				lcov_msg="You must have one of the following versions of lcov: $lcov_version_list (found: $lcov_version)."
>+				AC_MSG_ERROR([$lcov_msg])
>+				LCOV="exit 0;"
>+			;;
>+		esac
>+
>+		AS_IF([ test -z "$GENHTML" ], [
>+			AC_MSG_ERROR([Could not find genhtml from the lcov package])
>+		])
>+
>+		dnl Build the code coverage flags
>+		CODE_COVERAGE_CPPFLAGS="-DNDEBUG"
>+		CODE_COVERAGE_CFLAGS="-O0 -g -fprofile-arcs -ftest-coverage"
>+		CODE_COVERAGE_CXXFLAGS="-O0 -g -fprofile-arcs -ftest-coverage"
>+		CODE_COVERAGE_LDFLAGS="-lgcov"
>+
>+		AC_SUBST([CODE_COVERAGE_CPPFLAGS])
>+		AC_SUBST([CODE_COVERAGE_CFLAGS])
>+		AC_SUBST([CODE_COVERAGE_CXXFLAGS])
>+		AC_SUBST([CODE_COVERAGE_LDFLAGS])
>+	])
>+
>+[CODE_COVERAGE_RULES='
>+# Code coverage
>+#
>+# Optional:
>+#  - CODE_COVERAGE_DIRECTORY: Top-level directory for code coverage reporting.
>+#    Multiple directories may be specified, separated by whitespace.
>+#    (Default: $(top_builddir))
>+#  - CODE_COVERAGE_OUTPUT_FILE: Filename and path for the .info file generated
>+#    by lcov for code coverage. (Default:
>+#    $(PACKAGE_NAME)-$(PACKAGE_VERSION)-coverage.info)
>+#  - CODE_COVERAGE_OUTPUT_DIRECTORY: Directory for generated code coverage
>+#    reports to be created. (Default:
>+#    $(PACKAGE_NAME)-$(PACKAGE_VERSION)-coverage)
>+#  - CODE_COVERAGE_BRANCH_COVERAGE: Set to 1 to enforce branch coverage,
>+#    set to 0 to disable it and leave empty to stay with the default.
>+#    (Default: empty)
>+#  - CODE_COVERAGE_LCOV_SHOPTS_DEFAULT: Extra options shared between both lcov
>+#    instances. (Default: based on $CODE_COVERAGE_BRANCH_COVERAGE)
>+#  - CODE_COVERAGE_LCOV_SHOPTS: Extra options to shared between both lcov
>+#    instances. (Default: $CODE_COVERAGE_LCOV_SHOPTS_DEFAULT)
>+#  - CODE_COVERAGE_LCOV_OPTIONS_GCOVPATH: --gcov-tool pathtogcov
>+#  - CODE_COVERAGE_LCOV_OPTIONS_DEFAULT: Extra options to pass to the
>+#    collecting lcov instance. (Default: $CODE_COVERAGE_LCOV_OPTIONS_GCOVPATH)
>+#  - CODE_COVERAGE_LCOV_OPTIONS: Extra options to pass to the collecting lcov
>+#    instance. (Default: $CODE_COVERAGE_LCOV_OPTIONS_DEFAULT)
>+#  - CODE_COVERAGE_LCOV_RMOPTS_DEFAULT: Extra options to pass to the filtering
>+#    lcov instance. (Default: empty)
>+#  - CODE_COVERAGE_LCOV_RMOPTS: Extra options to pass to the filtering lcov
>+#    instance. (Default: $CODE_COVERAGE_LCOV_RMOPTS_DEFAULT)
>+#  - CODE_COVERAGE_GENHTML_OPTIONS_DEFAULT: Extra options to pass to the
>+#    genhtml instance. (Default: based on $CODE_COVERAGE_BRANCH_COVERAGE)
>+#  - CODE_COVERAGE_GENHTML_OPTIONS: Extra options to pass to the genhtml
>+#    instance. (Default: $CODE_COVERAGE_GENHTML_OPTIONS_DEFAULT)
>+#  - CODE_COVERAGE_IGNORE_PATTERN: Extra glob pattern of files to ignore
>+#
>+# The generated report will be titled using the $(PACKAGE_NAME) and
>+# $(PACKAGE_VERSION). In order to add the current git hash to the title,
>+# use the git-version-gen script, available online.
>+
>+# Optional variables
>+CODE_COVERAGE_DIRECTORY ?= $(top_builddir)
>+CODE_COVERAGE_OUTPUT_FILE ?= $(PACKAGE_NAME)-$(PACKAGE_VERSION)-coverage.info
>+CODE_COVERAGE_OUTPUT_DIRECTORY ?= $(PACKAGE_NAME)-$(PACKAGE_VERSION)-coverage
>+CODE_COVERAGE_BRANCH_COVERAGE ?=
>+CODE_COVERAGE_LCOV_SHOPTS_DEFAULT ?= $(if $(CODE_COVERAGE_BRANCH_COVERAGE),\
>+--rc lcov_branch_coverage=$(CODE_COVERAGE_BRANCH_COVERAGE))
>+CODE_COVERAGE_LCOV_SHOPTS ?= $(CODE_COVERAGE_LCOV_SHOPTS_DEFAULT)
>+CODE_COVERAGE_LCOV_OPTIONS_GCOVPATH ?= --gcov-tool "$(GCOV)"
>+CODE_COVERAGE_LCOV_OPTIONS_DEFAULT ?= $(CODE_COVERAGE_LCOV_OPTIONS_GCOVPATH)
>+CODE_COVERAGE_LCOV_OPTIONS ?= $(CODE_COVERAGE_LCOV_OPTIONS_DEFAULT)
>+CODE_COVERAGE_LCOV_RMOPTS_DEFAULT ?=
>+CODE_COVERAGE_LCOV_RMOPTS ?= $(CODE_COVERAGE_LCOV_RMOPTS_DEFAULT)
>+CODE_COVERAGE_GENHTML_OPTIONS_DEFAULT ?=\
>+$(if $(CODE_COVERAGE_BRANCH_COVERAGE),\
>+--rc genhtml_branch_coverage=$(CODE_COVERAGE_BRANCH_COVERAGE))
>+CODE_COVERAGE_GENHTML_OPTIONS ?= $(CODE_COVERAGE_GENHTML_OPTIONS_DEFAULTS)
>+CODE_COVERAGE_IGNORE_PATTERN ?=
>+
>+code_coverage_v_lcov_cap = $(code_coverage_v_lcov_cap_$(V))
>+code_coverage_v_lcov_cap_ = $(code_coverage_v_lcov_cap_$(AM_DEFAULT_VERBOSITY))
>+code_coverage_v_lcov_cap_0 = @echo "  LCOV   --capture"\
>+ $(CODE_COVERAGE_OUTPUT_FILE);
>+code_coverage_v_lcov_ign = $(code_coverage_v_lcov_ign_$(V))
>+code_coverage_v_lcov_ign_ = $(code_coverage_v_lcov_ign_$(AM_DEFAULT_VERBOSITY))
>+code_coverage_v_lcov_ign_0 = @echo "  LCOV   --remove /tmp/*"\
>+ $(CODE_COVERAGE_IGNORE_PATTERN);
>+code_coverage_v_genhtml = $(code_coverage_v_genhtml_$(V))
>+code_coverage_v_genhtml_ = $(code_coverage_v_genhtml_$(AM_DEFAULT_VERBOSITY))
>+code_coverage_v_genhtml_0 = @echo "  GEN   " $(CODE_COVERAGE_OUTPUT_DIRECTORY);
>+code_coverage_quiet = $(code_coverage_quiet_$(V))
>+code_coverage_quiet_ = $(code_coverage_quiet_$(AM_DEFAULT_VERBOSITY))
>+code_coverage_quiet_0 = --quiet
>+
>+# sanitizes the test-name: replaces with underscores: dashes and dots
>+code_coverage_sanitize = $(subst -,_,$(subst .,_,$(1)))
>+
>+# Use recursive makes in order to ignore errors during check
>+check-code-coverage:
>+ifeq ($(CODE_COVERAGE_ENABLED),yes)
>+	-$(A''M_V_at)$(MAKE) $(AM_MAKEFLAGS) -k check
>+	$(A''M_V_at)$(MAKE) $(AM_MAKEFLAGS) code-coverage-capture
>+else
>+	@echo "Need to reconfigure with --enable-code-coverage"
>+endif
>+
>+# Capture code coverage data
>+code-coverage-capture: code-coverage-capture-hook
>+ifeq ($(CODE_COVERAGE_ENABLED),yes)
>+	$(code_coverage_v_lcov_cap)$(LCOV) $(code_coverage_quiet) $(addprefix --directory ,$(CODE_COVERAGE_DIRECTORY)) --capture --output-file "$(CODE_COVERAGE_OUTPUT_FILE).tmp" --test-name "$(call code_coverage_sanitize,$(PACKAGE_NAME)-$(PACKAGE_VERSION))" --no-checksum --compat-libtool $(CODE_COVERAGE_LCOV_SHOPTS) $(CODE_COVERAGE_LCOV_OPTIONS)
>+	$(code_coverage_v_lcov_ign)$(LCOV) $(code_coverage_quiet) $(addprefix --directory ,$(CODE_COVERAGE_DIRECTORY)) --remove "$(CODE_COVERAGE_OUTPUT_FILE).tmp" "/tmp/*" $(CODE_COVERAGE_IGNORE_PATTERN) --output-file "$(CODE_COVERAGE_OUTPUT_FILE)" $(CODE_COVERAGE_LCOV_SHOPTS) $(CODE_COVERAGE_LCOV_RMOPTS)
>+	-@rm -f $(CODE_COVERAGE_OUTPUT_FILE).tmp
>+	$(code_coverage_v_genhtml)LANG=C $(GENHTML) $(code_coverage_quiet) $(addprefix --prefix ,$(CODE_COVERAGE_DIRECTORY)) --output-directory "$(CODE_COVERAGE_OUTPUT_DIRECTORY)" --title "$(PACKAGE_NAME)-$(PACKAGE_VERSION) Code Coverage" --legend --show-details "$(CODE_COVERAGE_OUTPUT_FILE)" $(CODE_COVERAGE_GENHTML_OPTIONS)
>+	@echo "file://$(abs_builddir)/$(CODE_COVERAGE_OUTPUT_DIRECTORY)/index.html"
>+else
>+	@echo "Need to reconfigure with --enable-code-coverage"
>+endif
>+
>+# Hook rule executed before code-coverage-capture, overridable by the user
>+code-coverage-capture-hook:
>+
>+ifeq ($(CODE_COVERAGE_ENABLED),yes)
>+clean: code-coverage-clean
>+code-coverage-clean:
>+	-$(LCOV) --directory $(top_builddir) -z
>+	-rm -rf $(CODE_COVERAGE_OUTPUT_FILE) $(CODE_COVERAGE_OUTPUT_FILE).tmp $(CODE_COVERAGE_OUTPUT_DIRECTORY)
>+	-find . -name "*.gcda" -o -name "*.gcov" -delete
>+endif
>+
>+GITIGNOREFILES ?=
>+GITIGNOREFILES += $(CODE_COVERAGE_OUTPUT_FILE) $(CODE_COVERAGE_OUTPUT_DIRECTORY)
>+
>+A''M_DISTCHECK_CONFIGURE_FLAGS ?=
>+A''M_DISTCHECK_CONFIGURE_FLAGS += --disable-code-coverage
>+
>+.PHONY: check-code-coverage code-coverage-capture code-coverage-capture-hook code-coverage-clean
>+']
>+
>+	AC_SUBST([CODE_COVERAGE_RULES])
>+	m4_ifdef([_AM_SUBST_NOTMAKE], [_AM_SUBST_NOTMAKE([CODE_COVERAGE_RULES])])
>+])
>diff --git a/test/Makefile.am b/test/Makefile.am
>index 0efd204..baabae3 100644
>--- a/test/Makefile.am
>+++ b/test/Makefile.am
>@@ -1,13 +1,14 @@
>-## the "name-test" subdir in fact contains a bunch of tests now that need a temporary bus 
>+## the "name-test" subdir in fact contains a bunch of tests now that need a temporary bus
> ## to be running to do stuff with. The directory should be renamed.
> ## We want to build the current directory first to pick up the testutils lib
>-SUBDIRS= . name-test 
>+SUBDIRS= . name-test
> DIST_SUBDIRS=name-test
> 
> CLEANFILES =
> EXTRA_DIST =
> 
> AM_CPPFLAGS = \
>+	$(CODE_COVERAGE_CPPFLAGS) \
> 	-I$(top_srcdir) \
> 	$(DBUS_STATIC_BUILD_CPPFLAGS) \
> 	-DDBUS_COMPILATION \
>@@ -17,6 +18,9 @@ AM_CPPFLAGS = \
> # improve backtraces from test stuff
> AM_LDFLAGS = @R_DYNAMIC_LDFLAG@
> 
>+AM_CFLAGS = \
>+	$(CODE_COVERAGE_CFLAGS)
>+
> noinst_LTLIBRARIES = libdbus-testutils.la
> 
> libdbus_testutils_la_SOURCES = \
>@@ -34,6 +38,7 @@ endif
> libdbus_testutils_la_LIBADD = \
> 	$(top_builddir)/dbus/libdbus-1.la \
> 	$(top_builddir)/dbus/libdbus-internal.la \
>+	$(CODE_COVERAGE_LDFLAGS) \
> 	$(NULL)
> 
> TEST_EXTENSIONS = .sh
>-- 
>2.7.4
>

Actions: View | Splinter Review

Attachments on bug 88922: 125739 | 125740 | 125753

Use of freedesktop.org services, including Bugzilla, is subject to our Code of Conduct. How we collect and use information is described in our Privacy Policy.