Attachment 142369 Details for Bug 107058 – pkgbuild for patched mesa

pkgbuild for patched mesa

PKGBUILD (text/plain), 2.72 KB, created by Danylo on 2018-11-05 13:26:30 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Danylo

Created: 2018-11-05 13:26:30 UTC

Size: 2.72 KB

patch

obsolete

># Maintainer: Lone_Wolf <lonewolf at xs4all dot nl>
># Contributor: Armin K. <krejzi at email dot com>
># Contributor: Kristian Klausen <klausenbusk@hotmail.com>
># Contributor: Egon Ashrafinia <e.ashrafinia@gmail.com>
># Contributor: Tavian Barnes <tavianator@gmail.com>
># Contributor: Jan de Groot <jgc@archlinux.org>
># Contributor: Andreas Radke <andyrtr@archlinux.org>
># Contributor: Thomas Dziedzic < gostrc at gmail >
># Contributor: Antti "Tera" Oja <antti.bofh@gmail.com>
># Contributor: Diego Jose <diegoxter1006@gmail.com>
>
>pkgbase=mesa-git
>pkgname=('mesa-git')
>pkgdesc="an open-source implementation of the OpenGL specification, git version"
>pkgver=19.0.0_devel.105580.ce837a5372
>pkgrel=1
>arch=('x86_64')
>makedepends=('git' 'python-mako' 'xorgproto'
>              'libxml2' 'libx11'  'libvdpau' 'libva' 'elfutils' 'libomxil-bellagio'
>              'ocl-icd' 'vulkan-icd-loader' 'libgcrypt'  'wayland' 'wayland-protocols' 'meson')
>depends=('libdrm' 'libxxf86vm' 'libxdamage' 'libxshmfence' 'libelf'
>         'libomxil-bellagio' 'libunwind' 'libglvnd' 'wayland' 'lm_sensors' 'libclc')
>optdepends=('opengl-man-pages: for the OpenGL API man pages')
>provides=('mesa' 'vulkan-intel' 'libva-mesa-driver' 'mesa-vdpau' 'vulkan-driver' 'opencl-mesa' 'opengl-driver' 'opencl-driver')
>conflicts=('mesa' 'opencl-mesa' 'vulkan-intel' 'libva-mesa-driver' 'mesa-vdpau')
>url="https://www.mesa3d.org"
>license=('custom')
>source=('mesa::git://anongit.freedesktop.org/mesa/mesa'
>        'add_mipmap_creation_logs.patch::https://bugs.freedesktop.org/attachment.cgi?id=142368'
>)
>sha512sums=('SKIP'
>            'SKIP'
>)
>
>pkgver() {
>    cd mesa
>    read -r _ver <VERSION
>    echo ${_ver/-/_}.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
>}
>
>prepare() {
>    cd mesa
>    patch -Np1 -i "${srcdir}/add_mipmap_creation_logs.patch"
>}
>
>build () {
>    if [  -d _build ]; then
>        rm -rf _build
>    fi
>    meson setup mesa _build \
>       -D b_ndebug=false \
>       -D buildtype=debug \
>       --wrap-mode=nofallback \
>       -D prefix=/usr \
>       -D sysconfdir=/etc \
>       -D platforms=x11,wayland,drm,surfaceless \
>       -D dri-drivers=i965 \
>       -D gallium-drivers= \
>       -D vulkan-drivers=intel \
>       -D dri3=true \
>       -D egl=true \
>       -D gbm=true \
>       -D gles1=true \
>       -D gles2=true \
>       -D glvnd=true \
>       -D glx=dri \
>       -D libunwind=true \
>       -D lmsensors=true \
>       -D shared-glapi=true \
>       -D valgrind=false \
>       -D tools=[]
>    meson configure _build
>    ninja -C _build
>}
>
>
>package_mesa-git() {
>
>  DESTDIR="$pkgdir" ninja -C _build install
>
>  # remove files provided by libglvnd
>  rm "$pkgdir"/usr/lib/libGLESv{1_CM,2}.so*
>   
>  # indirect rendering
>  ln -s /usr/lib/libGLX_mesa.so.0 ${pkgdir}/usr/lib/libGLX_indirect.so.0
>}
>

Actions: View

Attachments on bug 107058: 140667 | 140688 | 142368 | 142369 | 142379

Use of freedesktop.org services, including Bugzilla, is subject to our Code of Conduct. How we collect and use information is described in our Privacy Policy.