Attachment 46496 Details for Bug 19681 – [PATCH 1/5] Import tp-compiler-flag.m4 and tp-compiler-warnings.m4 from telepathy-glib

[patch] [PATCH 1/5] Import tp-compiler-flag.m4 and tp-compiler-warnings.m4 from telepathy-glib

0001-Import-tp-compiler-flag.m4-and-tp-compiler-warnings..patch (text/plain), 3.98 KB, created by Simon McVittie on 2011-05-09 11:11:29 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Simon McVittie

Created: 2011-05-09 11:11:29 UTC

Size: 3.98 KB

patch

obsolete

>From 4c3522fdb1b058ae6a423bf83fadd3157406bc49 Mon Sep 17 00:00:00 2001
>From: Simon McVittie <simon.mcvittie@collabora.co.uk>
>Date: Mon, 9 May 2011 18:32:51 +0100
>Subject: [PATCH 1/5] Import tp-compiler-flag.m4 and tp-compiler-warnings.m4
> from telepathy-glib
>
>Bug: https://bugs.freedesktop.org/show_bug.cgi?id=19681
>---
> m4/tp-compiler-flag.m4     |   43 ++++++++++++++++++++++++++++++++++++++
> m4/tp-compiler-warnings.m4 |   49 ++++++++++++++++++++++++++++++++++++++++++++
> 2 files changed, 92 insertions(+), 0 deletions(-)
> create mode 100644 m4/tp-compiler-flag.m4
> create mode 100644 m4/tp-compiler-warnings.m4
>
>diff --git a/m4/tp-compiler-flag.m4 b/m4/tp-compiler-flag.m4
>new file mode 100644
>index 0000000..06deaba
>--- /dev/null
>+++ b/m4/tp-compiler-flag.m4
>@@ -0,0 +1,43 @@
>+dnl A version of AS_COMPILER_FLAG that supports both C and C++.
>+dnl Based on:
>+
>+dnl as-compiler-flag.m4 0.1.0
>+dnl autostars m4 macro for detection of compiler flags
>+dnl David Schleef <ds@schleef.org>
>+dnl $Id: as-compiler-flag.m4,v 1.1 2005/06/18 18:02:46 burgerman Exp $
>+
>+dnl TP_COMPILER_FLAG(CFLAGS, ACTION-IF-ACCEPTED, [ACTION-IF-NOT-ACCEPTED])
>+dnl Tries to compile with the given CFLAGS and CXXFLAGS.
>+dnl
>+dnl Runs ACTION-IF-ACCEPTED if the compiler for the currently selected
>+dnl AC_LANG can compile with the flags, and ACTION-IF-NOT-ACCEPTED otherwise.
>+
>+AC_DEFUN([TP_COMPILER_FLAG],
>+[
>+  AC_MSG_CHECKING([to see if compiler understands $1])
>+
>+  save_CFLAGS="$CFLAGS"
>+  save_CXXFLAGS="$CXXFLAGS"
>+  CFLAGS="$CFLAGS $1"
>+  CXXFLAGS="$CXXFLAGS $1"
>+
>+  AC_TRY_COMPILE([ ], [], [flag_ok=yes], [flag_ok=no])
>+  CFLAGS="$save_CFLAGS"
>+  CXXFLAGS="$save_CXXFLAGS"
>+
>+  if test "X$flag_ok" = Xyes ; then
>+    $2
>+    true
>+  else
>+    $3
>+    true
>+  fi
>+  AC_MSG_RESULT([$flag_ok])
>+])
>+
>+dnl TP_ADD_COMPILER_FLAG(VARIABLE, CFLAGS)
>+dnl Append CFLAGS to VARIABLE if the compiler supports them.
>+AC_DEFUN([TP_ADD_COMPILER_FLAG],
>+[
>+  TP_COMPILER_FLAG([$2], [$1="[$]$1 $2"])
>+])
>diff --git a/m4/tp-compiler-warnings.m4 b/m4/tp-compiler-warnings.m4
>new file mode 100644
>index 0000000..ee4af31
>--- /dev/null
>+++ b/m4/tp-compiler-warnings.m4
>@@ -0,0 +1,49 @@
>+dnl TP_COMPILER_WARNINGS(VARIABLE, WERROR_BY_DEFAULT, DESIRABLE, UNDESIRABLE)
>+dnl $1 (VARIABLE): the variable to put flags into
>+dnl $2 (WERROR_BY_DEFAULT): a command returning true if -Werror should be the
>+dnl     default
>+dnl $3 (DESIRABLE): warning flags we want (e.g. all extra shadow)
>+dnl $4 (UNDESIRABLE): warning flags we don't want (e.g.
>+dnl   missing-field-initializers unused-parameter)
>+AC_DEFUN([TP_COMPILER_WARNINGS],
>+[
>+  AC_REQUIRE([AC_ARG_ENABLE])dnl
>+  AC_REQUIRE([AC_HELP_STRING])dnl
>+  AC_REQUIRE([TP_COMPILER_FLAG])dnl
>+
>+  tp_warnings=""
>+  for tp_flag in $3; do
>+    TP_COMPILER_FLAG([-W$tp_flag], [tp_warnings="$tp_warnings -W$tp_flag"])
>+  done
>+
>+  tp_error_flags="-Werror"
>+  TP_COMPILER_FLAG([-Werror], [tp_werror=yes], [tp_werror=no])
>+
>+  for tp_flag in $4; do
>+    TP_COMPILER_FLAG([-Wno-$tp_flag],
>+      [tp_warnings="$tp_warnings -Wno-$tp_flag"])
>+dnl Yes, we do need to use both -Wno-foo and -Wno-error=foo. Simon says:
>+dnl     some warnings we explicitly don't want, like unused-parameter, but
>+dnl     they're in -Wall. when a distro using cdbs compiles us, we have:
>+dnl       -Werror -Wno-unused-parameter      -Wall
>+dnl         ^ from us                         ^ from cdbs
>+dnl     which turns -Wunused-parameter back on, in effect
>+    TP_COMPILER_FLAG([-Wno-error=$tp_flag],
>+      [tp_error_flags="$tp_error_flags -Wno-error=$tp_flag"], [tp_werror=no])
>+  done
>+
>+  AC_ARG_ENABLE([Werror],
>+    AC_HELP_STRING([--disable-Werror],
>+      [compile without -Werror (normally enabled in development builds)]),
>+    tp_werror=$enableval, :)
>+
>+  if test "x$tp_werror" = xyes && $2; then
>+dnl We put -Wno-error=foo before -Wno-foo because clang interprets -Wall
>+dnl -Werror -Wno-foo -Wno-error=foo as âmake foo a non-fatal warningâ, but does
>+dnl what we want if you reverse them.
>+    $1="$tp_error_flags $tp_warnings"
>+  else
>+    $1="$tp_warnings"
>+  fi
>+
>+])
>-- 
>1.7.5.1
>

Actions: View | Splinter Review

Attachments on bug 19681: 22341 | 46496 | 46497 | 46498 | 46499 | 46500

Use of freedesktop.org services, including Bugzilla, is subject to our Code of Conduct. How we collect and use information is described in our Privacy Policy.