Attachment 43160 Details for Bug 34088 – Update autotools config

[patch] Update autotools config

0001-build-Update-autotools-configuration.patch (text/plain), 4.50 KB, created by Javier Jardón on 2011-02-09 06:39:59 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Javier Jardón

Created: 2011-02-09 06:39:59 UTC

Size: 4.50 KB

patch

obsolete

>From 03cf8f581701d42b8f6bf66a66a10cbcae6ce317 Mon Sep 17 00:00:00 2001
>From: =?UTF-8?q?Javier=20Jard=C3=B3n?= <javier.jardon@codethink.co.uk>
>Date: Wed, 9 Feb 2011 13:28:20 +0000
>Subject: [PATCH] build: Update autotools configuration
>
>Replace some deprecated autoconf macros and use the new libtool
>syntax
>---
> Makefile.am   |    2 +-
> autogen.sh    |   14 ++++----------
> configure.ac  |   47 +++++++++++++++++++++++++++++------------------
> m4/.gitignore |    5 +++++
> 4 files changed, 39 insertions(+), 29 deletions(-)
> create mode 100644 m4/.gitignore
>
>diff --git a/Makefile.am b/Makefile.am
>index 25d1747..a4d07f4 100644
>--- a/Makefile.am
>+++ b/Makefile.am
>@@ -18,7 +18,7 @@
> #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
> #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
> 
>-AUTOMAKE_OPTIONS = foreign
>+ACLOCAL_AMFLAGS = -I m4 ${ACLOCAL_FLAGS}
> 
> DISTCHECK_CONFIGURE_FLAGS = --enable-nouveau-experimental-api --enable-radeon-experimental-api
> 
>diff --git a/autogen.sh b/autogen.sh
>index 904cd67..30d679f 100755
>--- a/autogen.sh
>+++ b/autogen.sh
>@@ -1,12 +1,6 @@
> #! /bin/sh
> 
>-srcdir=`dirname $0`
>-test -z "$srcdir" && srcdir=.
>-
>-ORIGDIR=`pwd`
>-cd $srcdir
>-
>-autoreconf -v --install || exit 1
>-cd $ORIGDIR || exit $?
>-
>-$srcdir/configure --enable-maintainer-mode "$@"
>+test -n "$srcdir" || srcdir=`dirname "$0"`
>+test -n "$srcdir" || srcdir=.
>+autoreconf --force --install --verbose "$srcdir"
>+test -n "$NOCONFIGURE" || "$srcdir/configure" "$@"
>diff --git a/configure.ac b/configure.ac
>index b064665..d19ab87 100644
>--- a/configure.ac
>+++ b/configure.ac
>@@ -18,24 +18,34 @@
> #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
> #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
> 
>-AC_PREREQ(2.60)
>-AC_INIT([libdrm], 2.4.23, [dri-devel@lists.sourceforge.net], libdrm)
>-AC_USE_SYSTEM_EXTENSIONS
>+AC_PREREQ([2.63])
>+AC_INIT([libdrm],
>+        [2.4.23],
>+        [https://bugs.freedesktop.org//enter_bug.cgi?product=DRI],
>+        [libdrm])
>+
>+AC_CONFIG_HEADERS([config.h])
> AC_CONFIG_SRCDIR([Makefile.am])
>-AM_INIT_AUTOMAKE([dist-bzip2])
>+AC_CONFIG_MACRO_DIR([m4])
>+AC_CONFIG_AUX_DIR([build-aux])
>+
>+AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
>+AM_MAINTAINER_MODE([enable])
> 
>-AM_CONFIG_HEADER([config.h])
>+# Enable quiet compiles on automake 1.11.
>+m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
> 
>-AC_DISABLE_STATIC
>-AC_PROG_LIBTOOL
>+# Check for programs
> AC_PROG_CC
> 
>-AC_HEADER_STDC
>+AC_USE_SYSTEM_EXTENSIONS
> AC_SYS_LARGEFILE
> AC_FUNC_ALLOCA
> 
>-# Enable quiet compiles on automake 1.11.
>-m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
>+# Initialize libtool
>+LT_PREREQ([2.2])
>+LT_INIT([disable-static])
>+
> 
> PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
> AC_SUBST(PTHREADSTUBS_CFLAGS)
>@@ -43,9 +53,10 @@ AC_SUBST(PTHREADSTUBS_LIBS)
> 
> pkgconfigdir=${libdir}/pkgconfig
> AC_SUBST(pkgconfigdir)
>-AC_ARG_ENABLE(udev,	AS_HELP_STRING([--enable-udev],
>-				[Enable support for using udev instead of mknod (default: disabled)]),
>-				[UDEV=$enableval], [UDEV=no])
>+AC_ARG_ENABLE([udev],
>+              [AS_HELP_STRING([--enable-udev],
>+                              [Enable support for using udev instead of mknod (default: disabled)])],
>+              [UDEV=$enableval], [UDEV=no])
> 
> AC_ARG_ENABLE(libkms,
> 	      AS_HELP_STRING([--disable-libkms],
>@@ -188,12 +199,11 @@ if test "x$INTEL" != "xno" -o "x$RADEON" != "xno"; then
>     [
> 	    drm_cv_atomic_primitives="none"
> 
>-	    AC_TRY_LINK([
>+	    AC_LINK_IFELSE([AC_LANG_PROGRAM([[
>     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
>     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
>-    ], [],
>-	      drm_cv_atomic_primitives="Intel"
>-	      )
>+                                            ]],[[]])],
>+                           [drm_cv_atomic_primitives="Intel"],[])
> 
> 	    if test "x$drm_cv_atomic_primitives" = "xnone"; then
> 		    AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
>@@ -252,7 +262,7 @@ AC_ARG_WITH([kernel-source],
> AC_SUBST(kernel_source)
> 
> AC_SUBST(WARN_CFLAGS)
>-AC_OUTPUT([
>+AC_CONFIG_FILES([
> 	Makefile
> 	libkms/Makefile
> 	libkms/libkms.pc
>@@ -270,6 +280,7 @@ AC_OUTPUT([
> 	include/Makefile
> 	include/drm/Makefile
> 	libdrm.pc])
>+AC_OUTPUT
> 
> echo ""
> echo "$PACKAGE_STRING will be compiled with:"
>diff --git a/m4/.gitignore b/m4/.gitignore
>new file mode 100644
>index 0000000..464ba5c
>--- /dev/null
>+++ b/m4/.gitignore
>@@ -0,0 +1,5 @@
>+libtool.m4
>+lt~obsolete.m4
>+ltoptions.m4
>+ltsugar.m4
>+ltversion.m4
>-- 
>1.7.4
>

Actions: View | Splinter Review

Attachments on bug 34088: 43160

Use of freedesktop.org services, including Bugzilla, is subject to our Code of Conduct. How we collect and use information is described in our Privacy Policy.