Attachment 75399 Details for Bug 61334 – use autoreconf and add m4 files

[patch] use autoreconf and add m4 files

0003-use-autoreconf-add-needed-m4-files-so-that-they-are-.patch (text/plain), 36.89 KB, created by Vincent Torri on 2013-02-23 09:08:19 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Vincent Torri

Created: 2013-02-23 09:08:19 UTC

Size: 36.89 KB

patch

obsolete

>From 069a9e22c93ebef4f8af93bffeecd9206cf11075 Mon Sep 17 00:00:00 2001
>From: Vincent Torri <vincent.torri@gmail.com>
>Date: Sat, 23 Feb 2013 09:56:54 +0100
>Subject: [PATCH 3/3] use autoreconf, add needed m4 files so that they are always available
>
>---
> Makefile.am        |    6 +
> autogen.sh         |   56 +------
> configure.ac       |    6 +-
> m4/glib-gettext.m4 |  436 ++++++++++++++++++++++++++++++++++++++++++++++++++++
> m4/intltool.m4     |  216 ++++++++++++++++++++++++++
> m4/nls.m4          |   32 ++++
> m4/pkg.m4          |  199 ++++++++++++++++++++++++
> 7 files changed, 896 insertions(+), 55 deletions(-)
> create mode 100644 m4/glib-gettext.m4
> create mode 100644 m4/intltool.m4
> create mode 100644 m4/nls.m4
> create mode 100644 m4/pkg.m4
>
>diff --git a/Makefile.am b/Makefile.am
>index dfffa3b..efbc3eb 100644
>--- a/Makefile.am
>+++ b/Makefile.am
>@@ -1,3 +1,5 @@
>+ACLOCAL_AMFLAGS = -I m4
>+
> SUBDIRS=. po
> 
> AM_CPPFLAGS = $(ALL_CFLAGS)
>@@ -33,6 +35,10 @@ EXTRA_DIST = \
> 	HACKING				\
> 	$(man_MANS)			\
> 	shared-mime-info.pc.in		\
>+	m4/glib-gettext.m4		\
>+	m4/intltool.m4			\
>+	m4/nls.m4			\
>+	m4/pkg.m4			\
> 	po/shared-mime-info.pot
> 
> CLEANFILES = freedesktop.org.xml po/stamp-it
>diff --git a/autogen.sh b/autogen.sh
>index 1d1ddb9..0aa618b 100755
>--- a/autogen.sh
>+++ b/autogen.sh
>@@ -1,58 +1,10 @@
> #!/bin/sh
> # Run this to generate all the initial makefiles, etc.
> 
>-set -e
>- 
>-srcdir=`dirname $0`
>-test -z "$srcdir" && srcdir=.
>-
>-ORIGDIR=`pwd`
>-cd $srcdir
>-
>-ARGV0=$0
>-
>-if test -z "$ACLOCAL_FLAGS"; then
>-    acdir=`aclocal --print-ac-dir`
>-    if [ ! -f $acdir/pkg.m4 ]; then
>-    echo "$ARGV0: Error: Could not find pkg-config macros."
>-    echo "        (Looked in $acdir/pkg.m4)"
>-    echo "        If pkg.m4 is available in /another/directory, please set"
>-    echo "        ACLOCAL_FLAGS=\"-I /another/directory\""
>-    echo "        Otherwise, please install pkg-config."
>-    echo ""
>-    echo "pkg-config is available from:"
>-    echo "http://www.freedesktop.org/software/pkgconfig/"
>-    exit 1
>-    fi
>-fi
>-
>-if test -z "$*"; then
>-    echo "$ARGV0:Note: \`./configure' will be run with no arguments."
>-	echo "If you wish to pass any to it, please specify them on the"
>-	echo "\`$0' command line."
>-  echo
>-fi
>-
>-do_cmd() {
>-    echo "$ARGV0: running \`$@'"
>-    $@
>-}
>-
>-# not required for shared-mime-info, skip.
>-# do_cmd libtoolize --force --copy
>-
>-do_cmd intltoolize --force
>-
>-do_cmd aclocal ${ACLOCAL_FLAGS}
>-
>-do_cmd autoheader
>-
>-do_cmd automake --add-missing
>-
>-do_cmd autoconf
>-
>-cd $ORIGDIR || exit $?
>+echo "autogen.sh: running: intltoolize --force"
>+intltoolize --force || exit 1
>+autoreconf -vif || exit 1
> 
> if test -z "$NOCONFIGURE"; then
>-    do_cmd $srcdir/configure --enable-maintainer-mode ${1+"$@"} && echo "Now type \`make' to compile" || exit 1
>+    ./configure "$@" && echo "Now type \`make' to compile" || exit 1
> fi
>diff --git a/configure.ac b/configure.ac
>index ef41555..56062a0 100644
>--- a/configure.ac
>+++ b/configure.ac
>@@ -3,6 +3,7 @@ AC_INIT([shared-mime-info],[1.1],[https://bugs.freedesktop.org/enter_bug.cgi?pro
> AM_INIT_AUTOMAKE([1.9 foreign no-dist-gzip dist-xz check-news])
> 
> AC_CONFIG_HEADERS([config.h])
>+AC_CONFIG_MACRO_DIR([m4])
> 
> # Enable silent build when available (Automake 1.11)
> m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
>@@ -13,13 +14,12 @@ AC_PROG_CC
> dnl Checks for typedefs, structures, and compiler characteristics.
> AC_C_CONST
> 
>-
>-IT_PROG_INTLTOOL([0.35.0])
>-
> GETTEXT_PACKAGE=shared-mime-info
> AC_SUBST(GETTEXT_PACKAGE)
> AM_GLIB_GNU_GETTEXT
> 
>+IT_PROG_INTLTOOL([0.35.0])
>+
> dnl Check for cross compiling
> AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
> 
>diff --git a/m4/glib-gettext.m4 b/m4/glib-gettext.m4
>new file mode 100644
>index 0000000..c64e64f
>--- /dev/null
>+++ b/m4/glib-gettext.m4
>@@ -0,0 +1,436 @@
>+# Copyright (C) 1995-2002 Free Software Foundation, Inc.
>+# Copyright (C) 2001-2003,2004 Red Hat, Inc.
>+#
>+# This file is free software, distributed under the terms of the GNU
>+# General Public License.  As a special exception to the GNU General
>+# Public License, this file may be distributed as part of a program
>+# that contains a configuration script generated by Autoconf, under
>+# the same distribution terms as the rest of that program.
>+#
>+# This file can be copied and used freely without restrictions.  It can
>+# be used in projects which are not available under the GNU Public License
>+# but which still want to provide support for the GNU gettext functionality.
>+#
>+# Macro to add for using GNU gettext.
>+# Ulrich Drepper <drepper@cygnus.com>, 1995, 1996
>+#
>+# Modified to never use included libintl. 
>+# Owen Taylor <otaylor@redhat.com>, 12/15/1998
>+#
>+# Major rework to remove unused code
>+# Owen Taylor <otaylor@redhat.com>, 12/11/2002
>+#
>+# Added better handling of ALL_LINGUAS from GNU gettext version 
>+# written by Bruno Haible, Owen Taylor <otaylor.redhat.com> 5/30/3002
>+#
>+# Modified to require ngettext
>+# Matthias Clasen <mclasen@redhat.com> 08/06/2004
>+#
>+# We need this here as well, since someone might use autoconf-2.5x
>+# to configure GLib then an older version to configure a package
>+# using AM_GLIB_GNU_GETTEXT
>+AC_PREREQ(2.53)
>+
>+dnl
>+dnl We go to great lengths to make sure that aclocal won't 
>+dnl try to pull in the installed version of these macros
>+dnl when running aclocal in the glib directory.
>+dnl
>+m4_copy([AC_DEFUN],[glib_DEFUN])
>+m4_copy([AC_REQUIRE],[glib_REQUIRE])
>+dnl
>+dnl At the end, if we're not within glib, we'll define the public
>+dnl definitions in terms of our private definitions.
>+dnl
>+
>+# GLIB_LC_MESSAGES
>+#--------------------
>+glib_DEFUN([GLIB_LC_MESSAGES],
>+  [AC_CHECK_HEADERS([locale.h])
>+    if test $ac_cv_header_locale_h = yes; then
>+    AC_CACHE_CHECK([for LC_MESSAGES], am_cv_val_LC_MESSAGES,
>+      [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
>+       am_cv_val_LC_MESSAGES=yes, am_cv_val_LC_MESSAGES=no)])
>+    if test $am_cv_val_LC_MESSAGES = yes; then
>+      AC_DEFINE(HAVE_LC_MESSAGES, 1,
>+        [Define if your <locale.h> file defines LC_MESSAGES.])
>+    fi
>+  fi])
>+
>+# GLIB_PATH_PROG_WITH_TEST
>+#----------------------------
>+dnl GLIB_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
>+dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
>+glib_DEFUN([GLIB_PATH_PROG_WITH_TEST],
>+[# Extract the first word of "$2", so it can be a program name with args.
>+set dummy $2; ac_word=[$]2
>+AC_MSG_CHECKING([for $ac_word])
>+AC_CACHE_VAL(ac_cv_path_$1,
>+[case "[$]$1" in
>+  /*)
>+  ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
>+  ;;
>+  *)
>+  IFS="${IFS= 	}"; ac_save_ifs="$IFS"; IFS="${IFS}:"
>+  for ac_dir in ifelse([$5], , $PATH, [$5]); do
>+    test -z "$ac_dir" && ac_dir=.
>+    if test -f $ac_dir/$ac_word; then
>+      if [$3]; then
>+	ac_cv_path_$1="$ac_dir/$ac_word"
>+	break
>+      fi
>+    fi
>+  done
>+  IFS="$ac_save_ifs"
>+dnl If no 4th arg is given, leave the cache variable unset,
>+dnl so AC_PATH_PROGS will keep looking.
>+ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
>+])dnl
>+  ;;
>+esac])dnl
>+$1="$ac_cv_path_$1"
>+if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
>+  AC_MSG_RESULT([$]$1)
>+else
>+  AC_MSG_RESULT(no)
>+fi
>+AC_SUBST($1)dnl
>+])
>+
>+# GLIB_WITH_NLS
>+#-----------------
>+glib_DEFUN([GLIB_WITH_NLS],
>+  dnl NLS is obligatory
>+  [USE_NLS=yes
>+    AC_SUBST(USE_NLS)
>+
>+    gt_cv_have_gettext=no
>+
>+    CATOBJEXT=NONE
>+    XGETTEXT=:
>+    INTLLIBS=
>+
>+    AC_CHECK_HEADER(libintl.h,
>+     [gt_cv_func_dgettext_libintl="no"
>+      libintl_extra_libs=""
>+
>+      #
>+      # First check in libc
>+      #
>+      AC_CACHE_CHECK([for ngettext in libc], gt_cv_func_ngettext_libc,
>+        [AC_TRY_LINK([
>+#include <libintl.h>
>+],
>+         [return !ngettext ("","", 1)],
>+	  gt_cv_func_ngettext_libc=yes,
>+          gt_cv_func_ngettext_libc=no)
>+        ])
>+  
>+      if test "$gt_cv_func_ngettext_libc" = "yes" ; then
>+	      AC_CACHE_CHECK([for dgettext in libc], gt_cv_func_dgettext_libc,
>+        	[AC_TRY_LINK([
>+#include <libintl.h>
>+],
>+	          [return !dgettext ("","")],
>+		  gt_cv_func_dgettext_libc=yes,
>+	          gt_cv_func_dgettext_libc=no)
>+        	])
>+      fi
>+  
>+      if test "$gt_cv_func_ngettext_libc" = "yes" ; then
>+        AC_CHECK_FUNCS(bind_textdomain_codeset)
>+      fi
>+
>+      #
>+      # If we don't have everything we want, check in libintl
>+      #
>+      if test "$gt_cv_func_dgettext_libc" != "yes" \
>+	 || test "$gt_cv_func_ngettext_libc" != "yes" \
>+         || test "$ac_cv_func_bind_textdomain_codeset" != "yes" ; then
>+        
>+        AC_CHECK_LIB(intl, bindtextdomain,
>+	    [AC_CHECK_LIB(intl, ngettext,
>+		    [AC_CHECK_LIB(intl, dgettext,
>+			          gt_cv_func_dgettext_libintl=yes)])])
>+
>+	if test "$gt_cv_func_dgettext_libintl" != "yes" ; then
>+	  AC_MSG_CHECKING([if -liconv is needed to use gettext])
>+	  AC_MSG_RESULT([])
>+  	  AC_CHECK_LIB(intl, ngettext,
>+          	[AC_CHECK_LIB(intl, dcgettext,
>+		       [gt_cv_func_dgettext_libintl=yes
>+			libintl_extra_libs=-liconv],
>+			:,-liconv)],
>+		:,-liconv)
>+        fi
>+
>+        #
>+        # If we found libintl, then check in it for bind_textdomain_codeset();
>+        # we'll prefer libc if neither have bind_textdomain_codeset(),
>+        # and both have dgettext and ngettext
>+        #
>+        if test "$gt_cv_func_dgettext_libintl" = "yes" ; then
>+          glib_save_LIBS="$LIBS"
>+          LIBS="$LIBS -lintl $libintl_extra_libs"
>+          unset ac_cv_func_bind_textdomain_codeset
>+          AC_CHECK_FUNCS(bind_textdomain_codeset)
>+          LIBS="$glib_save_LIBS"
>+
>+          if test "$ac_cv_func_bind_textdomain_codeset" = "yes" ; then
>+            gt_cv_func_dgettext_libc=no
>+          else
>+            if test "$gt_cv_func_dgettext_libc" = "yes" \
>+		&& test "$gt_cv_func_ngettext_libc" = "yes"; then
>+              gt_cv_func_dgettext_libintl=no
>+            fi
>+          fi
>+        fi
>+      fi
>+
>+      if test "$gt_cv_func_dgettext_libc" = "yes" \
>+	|| test "$gt_cv_func_dgettext_libintl" = "yes"; then
>+        gt_cv_have_gettext=yes
>+      fi
>+  
>+      if test "$gt_cv_func_dgettext_libintl" = "yes"; then
>+        INTLLIBS="-lintl $libintl_extra_libs"
>+      fi
>+  
>+      if test "$gt_cv_have_gettext" = "yes"; then
>+	AC_DEFINE(HAVE_GETTEXT,1,
>+	  [Define if the GNU gettext() function is already present or preinstalled.])
>+	GLIB_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
>+	  [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], no)dnl
>+	if test "$MSGFMT" != "no"; then
>+          glib_save_LIBS="$LIBS"
>+          LIBS="$LIBS $INTLLIBS"
>+	  AC_CHECK_FUNCS(dcgettext)
>+	  MSGFMT_OPTS=
>+	  AC_MSG_CHECKING([if msgfmt accepts -c])
>+	  GLIB_RUN_PROG([$MSGFMT -c -o /dev/null],[
>+msgid ""
>+msgstr ""
>+"Content-Type: text/plain; charset=UTF-8\n"
>+"Project-Id-Version: test 1.0\n"
>+"PO-Revision-Date: 2007-02-15 12:01+0100\n"
>+"Last-Translator: test <foo@bar.xx>\n"
>+"Language-Team: C <LL@li.org>\n"
>+"MIME-Version: 1.0\n"
>+"Content-Transfer-Encoding: 8bit\n"
>+], [MSGFMT_OPTS=-c; AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no])])
>+	  AC_SUBST(MSGFMT_OPTS)
>+	  AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
>+	  GLIB_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
>+	    [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
>+	  AC_TRY_LINK(, [extern int _nl_msg_cat_cntr;
>+			 return _nl_msg_cat_cntr],
>+	    [CATOBJEXT=.gmo 
>+             DATADIRNAME=share],
>+	    [case $host in
>+	    *-*-solaris*)
>+	    dnl On Solaris, if bind_textdomain_codeset is in libc,
>+	    dnl GNU format message catalog is always supported,
>+            dnl since both are added to the libc all together.
>+	    dnl Hence, we'd like to go with DATADIRNAME=share and
>+	    dnl and CATOBJEXT=.gmo in this case.
>+            AC_CHECK_FUNC(bind_textdomain_codeset,
>+	      [CATOBJEXT=.gmo 
>+               DATADIRNAME=share],
>+	      [CATOBJEXT=.mo
>+               DATADIRNAME=lib])
>+	    ;;
>+	    *-*-openbsd*)
>+	    CATOBJEXT=.mo
>+            DATADIRNAME=share
>+	    ;;
>+	    *)
>+	    CATOBJEXT=.mo
>+            DATADIRNAME=lib
>+	    ;;
>+	    esac])
>+          LIBS="$glib_save_LIBS"
>+	  INSTOBJEXT=.mo
>+	else
>+	  gt_cv_have_gettext=no
>+	fi
>+      fi
>+    ])
>+
>+    if test "$gt_cv_have_gettext" = "yes" ; then
>+      AC_DEFINE(ENABLE_NLS, 1,
>+        [always defined to indicate that i18n is enabled])
>+    fi
>+
>+    dnl Test whether we really found GNU xgettext.
>+    if test "$XGETTEXT" != ":"; then
>+      dnl If it is not GNU xgettext we define it as : so that the
>+      dnl Makefiles still can work.
>+      if $XGETTEXT --omit-header /dev/null 2> /dev/null; then
>+        : ;
>+      else
>+        AC_MSG_RESULT(
>+	  [found xgettext program is not GNU xgettext; ignore it])
>+        XGETTEXT=":"
>+      fi
>+    fi
>+
>+    # We need to process the po/ directory.
>+    POSUB=po
>+
>+    AC_OUTPUT_COMMANDS(
>+      [case "$CONFIG_FILES" in *po/Makefile.in*)
>+        sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile
>+      esac])
>+
>+    dnl These rules are solely for the distribution goal.  While doing this
>+    dnl we only have to keep exactly one list of the available catalogs
>+    dnl in configure.ac.
>+    for lang in $ALL_LINGUAS; do
>+      GMOFILES="$GMOFILES $lang.gmo"
>+      POFILES="$POFILES $lang.po"
>+    done
>+
>+    dnl Make all variables we use known to autoconf.
>+    AC_SUBST(CATALOGS)
>+    AC_SUBST(CATOBJEXT)
>+    AC_SUBST(DATADIRNAME)
>+    AC_SUBST(GMOFILES)
>+    AC_SUBST(INSTOBJEXT)
>+    AC_SUBST(INTLLIBS)
>+    AC_SUBST(PO_IN_DATADIR_TRUE)
>+    AC_SUBST(PO_IN_DATADIR_FALSE)
>+    AC_SUBST(POFILES)
>+    AC_SUBST(POSUB)
>+  ])
>+
>+# AM_GLIB_GNU_GETTEXT
>+# -------------------
>+# Do checks necessary for use of gettext. If a suitable implementation 
>+# of gettext is found in either in libintl or in the C library,
>+# it will set INTLLIBS to the libraries needed for use of gettext
>+# and AC_DEFINE() HAVE_GETTEXT and ENABLE_NLS. (The shell variable
>+# gt_cv_have_gettext will be set to "yes".) It will also call AC_SUBST()
>+# on various variables needed by the Makefile.in.in installed by 
>+# glib-gettextize.
>+dnl
>+glib_DEFUN([GLIB_GNU_GETTEXT],
>+  [AC_REQUIRE([AC_PROG_CC])dnl
>+   AC_REQUIRE([AC_HEADER_STDC])dnl
>+   
>+   GLIB_LC_MESSAGES
>+   GLIB_WITH_NLS
>+
>+   if test "$gt_cv_have_gettext" = "yes"; then
>+     if test "x$ALL_LINGUAS" = "x"; then
>+       LINGUAS=
>+     else
>+       AC_MSG_CHECKING(for catalogs to be installed)
>+       NEW_LINGUAS=
>+       for presentlang in $ALL_LINGUAS; do
>+         useit=no
>+         if test "%UNSET%" != "${LINGUAS-%UNSET%}"; then
>+           desiredlanguages="$LINGUAS"
>+         else
>+           desiredlanguages="$ALL_LINGUAS"
>+         fi
>+         for desiredlang in $desiredlanguages; do
>+ 	   # Use the presentlang catalog if desiredlang is
>+           #   a. equal to presentlang, or
>+           #   b. a variant of presentlang (because in this case,
>+           #      presentlang can be used as a fallback for messages
>+           #      which are not translated in the desiredlang catalog).
>+           case "$desiredlang" in
>+             "$presentlang"*) useit=yes;;
>+           esac
>+         done
>+         if test $useit = yes; then
>+           NEW_LINGUAS="$NEW_LINGUAS $presentlang"
>+         fi
>+       done
>+       LINGUAS=$NEW_LINGUAS
>+       AC_MSG_RESULT($LINGUAS)
>+     fi
>+
>+     dnl Construct list of names of catalog files to be constructed.
>+     if test -n "$LINGUAS"; then
>+       for lang in $LINGUAS; do CATALOGS="$CATALOGS $lang$CATOBJEXT"; done
>+     fi
>+   fi
>+
>+   dnl If the AC_CONFIG_AUX_DIR macro for autoconf is used we possibly
>+   dnl find the mkinstalldirs script in another subdir but ($top_srcdir).
>+   dnl Try to locate is.
>+   MKINSTALLDIRS=
>+   if test -n "$ac_aux_dir"; then
>+     MKINSTALLDIRS="$ac_aux_dir/mkinstalldirs"
>+   fi
>+   if test -z "$MKINSTALLDIRS"; then
>+     MKINSTALLDIRS="\$(top_srcdir)/mkinstalldirs"
>+   fi
>+   AC_SUBST(MKINSTALLDIRS)
>+
>+   dnl Generate list of files to be processed by xgettext which will
>+   dnl be included in po/Makefile.
>+   test -d po || mkdir po
>+   if test "x$srcdir" != "x."; then
>+     if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
>+       posrcprefix="$srcdir/"
>+     else
>+       posrcprefix="../$srcdir/"
>+     fi
>+   else
>+     posrcprefix="../"
>+   fi
>+   rm -f po/POTFILES
>+   sed -e "/^#/d" -e "/^\$/d" -e "s,.*,	$posrcprefix& \\\\," -e "\$s/$.*$ \\\\/\1/" \
>+	< $srcdir/po/POTFILES.in > po/POTFILES
>+  ])
>+
>+# AM_GLIB_DEFINE_LOCALEDIR(VARIABLE)
>+# -------------------------------
>+# Define VARIABLE to the location where catalog files will
>+# be installed by po/Makefile.
>+glib_DEFUN([GLIB_DEFINE_LOCALEDIR],
>+[glib_REQUIRE([GLIB_GNU_GETTEXT])dnl
>+glib_save_prefix="$prefix"
>+glib_save_exec_prefix="$exec_prefix"
>+glib_save_datarootdir="$datarootdir"
>+test "x$prefix" = xNONE && prefix=$ac_default_prefix
>+test "x$exec_prefix" = xNONE && exec_prefix=$prefix
>+datarootdir=`eval echo "${datarootdir}"`
>+if test "x$CATOBJEXT" = "x.mo" ; then
>+  localedir=`eval echo "${libdir}/locale"`
>+else
>+  localedir=`eval echo "${datadir}/locale"`
>+fi
>+prefix="$glib_save_prefix"
>+exec_prefix="$glib_save_exec_prefix"
>+datarootdir="$glib_save_datarootdir"
>+AC_DEFINE_UNQUOTED($1, "$localedir",
>+  [Define the location where the catalogs will be installed])
>+])
>+
>+dnl
>+dnl Now the definitions that aclocal will find
>+dnl
>+ifdef(glib_configure_ac,[],[
>+AC_DEFUN([AM_GLIB_GNU_GETTEXT],[GLIB_GNU_GETTEXT($@)])
>+AC_DEFUN([AM_GLIB_DEFINE_LOCALEDIR],[GLIB_DEFINE_LOCALEDIR($@)])
>+])dnl
>+
>+# GLIB_RUN_PROG(PROGRAM, TEST-FILE, [ACTION-IF-PASS], [ACTION-IF-FAIL])
>+# 
>+# Create a temporary file with TEST-FILE as its contents and pass the
>+# file name to PROGRAM.  Perform ACTION-IF-PASS if PROGRAM exits with
>+# 0 and perform ACTION-IF-FAIL for any other exit status.
>+AC_DEFUN([GLIB_RUN_PROG],
>+[cat >conftest.foo <<_ACEOF
>+$2
>+_ACEOF
>+if AC_RUN_LOG([$1 conftest.foo]); then
>+  m4_ifval([$3], [$3], [:])
>+m4_ifvaln([$4], [else $4])dnl
>+echo "$as_me: failed input was:" >&AS_MESSAGE_LOG_FD
>+sed 's/^/| /' conftest.foo >&AS_MESSAGE_LOG_FD
>+fi])
>+
>diff --git a/m4/intltool.m4 b/m4/intltool.m4
>new file mode 100644
>index 0000000..839e855
>--- /dev/null
>+++ b/m4/intltool.m4
>@@ -0,0 +1,216 @@
>+## intltool.m4 - Configure intltool for the target system. -*-Shell-script-*-
>+## Copyright (C) 2001 Eazel, Inc.
>+## Author: Maciej Stachowiak <mjs@noisehavoc.org>
>+##         Kenneth Christiansen <kenneth@gnu.org>
>+##
>+## This program is free software; you can redistribute it and/or modify
>+## it under the terms of the GNU General Public License as published by
>+## the Free Software Foundation; either version 2 of the License, or
>+## (at your option) any later version.
>+##
>+## This program is distributed in the hope that it will be useful, but
>+## WITHOUT ANY WARRANTY; without even the implied warranty of
>+## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
>+## General Public License for more details.
>+##
>+## You should have received a copy of the GNU General Public License
>+## along with this program; if not, write to the Free Software
>+## Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
>+##
>+## As a special exception to the GNU General Public License, if you
>+## distribute this file as part of a program that contains a
>+## configuration script generated by Autoconf, you may include it under
>+## the same distribution terms that you use for the rest of that program.
>+
>+dnl IT_PROG_INTLTOOL([MINIMUM-VERSION], [no-xml])
>+# serial 40 IT_PROG_INTLTOOL
>+AC_DEFUN([IT_PROG_INTLTOOL], [
>+AC_PREREQ([2.50])dnl
>+AC_REQUIRE([AM_NLS])dnl
>+
>+case "$am__api_version" in
>+    1.[01234])
>+	AC_MSG_ERROR([Automake 1.5 or newer is required to use intltool])
>+    ;;
>+    *)
>+    ;;
>+esac
>+
>+if test -n "$1"; then
>+    AC_MSG_CHECKING([for intltool >= $1])
>+
>+    INTLTOOL_REQUIRED_VERSION_AS_INT=`echo $1 | awk -F. '{ print $ 1 * 1000 + $ 2 * 100 + $ 3; }'`
>+    INTLTOOL_APPLIED_VERSION=`intltool-update --version | head -1 | cut -d" " -f3`
>+    [INTLTOOL_APPLIED_VERSION_AS_INT=`echo $INTLTOOL_APPLIED_VERSION | awk -F. '{ print $ 1 * 1000 + $ 2 * 100 + $ 3; }'`
>+    ]
>+    AC_MSG_RESULT([$INTLTOOL_APPLIED_VERSION found])
>+    test "$INTLTOOL_APPLIED_VERSION_AS_INT" -ge "$INTLTOOL_REQUIRED_VERSION_AS_INT" ||
>+	AC_MSG_ERROR([Your intltool is too old.  You need intltool $1 or later.])
>+fi
>+
>+AC_PATH_PROG(INTLTOOL_UPDATE, [intltool-update])
>+AC_PATH_PROG(INTLTOOL_MERGE, [intltool-merge])
>+AC_PATH_PROG(INTLTOOL_EXTRACT, [intltool-extract])
>+if test -z "$INTLTOOL_UPDATE" -o -z "$INTLTOOL_MERGE" -o -z "$INTLTOOL_EXTRACT"; then
>+    AC_MSG_ERROR([The intltool scripts were not found. Please install intltool.])
>+fi
>+
>+  INTLTOOL_DESKTOP_RULE='%.desktop:   %.desktop.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+INTLTOOL_DIRECTORY_RULE='%.directory: %.directory.in $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+     INTLTOOL_KEYS_RULE='%.keys:      %.keys.in      $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -k -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+     INTLTOOL_PROP_RULE='%.prop:      %.prop.in      $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+      INTLTOOL_OAF_RULE='%.oaf:       %.oaf.in       $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -o -p $(top_srcdir)/po $< [$]@'
>+     INTLTOOL_PONG_RULE='%.pong:      %.pong.in      $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -x -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+   INTLTOOL_SERVER_RULE='%.server:    %.server.in    $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -o -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+    INTLTOOL_SHEET_RULE='%.sheet:     %.sheet.in     $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -x -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+INTLTOOL_SOUNDLIST_RULE='%.soundlist: %.soundlist.in $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+       INTLTOOL_UI_RULE='%.ui:        %.ui.in        $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -x -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+      INTLTOOL_XML_RULE='%.xml:       %.xml.in       $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -x -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+      INTLTOOL_XML_NOMERGE_RULE='%.xml:       %.xml.in       $(INTLTOOL_MERGE) ; LC_ALL=C $(INTLTOOL_MERGE) -x -u /tmp $< [$]@' 
>+      INTLTOOL_XAM_RULE='%.xam:       %.xml.in       $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -x -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+      INTLTOOL_KBD_RULE='%.kbd:       %.kbd.in       $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -x -u -m -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+    INTLTOOL_CAVES_RULE='%.caves:     %.caves.in     $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+  INTLTOOL_SCHEMAS_RULE='%.schemas:   %.schemas.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -s -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+    INTLTOOL_THEME_RULE='%.theme:     %.theme.in     $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@' 
>+    INTLTOOL_SERVICE_RULE='%.service: %.service.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
>+   INTLTOOL_POLICY_RULE='%.policy:    %.policy.in    $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -x -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
>+
>+_IT_SUBST(INTLTOOL_DESKTOP_RULE)
>+_IT_SUBST(INTLTOOL_DIRECTORY_RULE)
>+_IT_SUBST(INTLTOOL_KEYS_RULE)
>+_IT_SUBST(INTLTOOL_PROP_RULE)
>+_IT_SUBST(INTLTOOL_OAF_RULE)
>+_IT_SUBST(INTLTOOL_PONG_RULE)
>+_IT_SUBST(INTLTOOL_SERVER_RULE)
>+_IT_SUBST(INTLTOOL_SHEET_RULE)
>+_IT_SUBST(INTLTOOL_SOUNDLIST_RULE)
>+_IT_SUBST(INTLTOOL_UI_RULE)
>+_IT_SUBST(INTLTOOL_XAM_RULE)
>+_IT_SUBST(INTLTOOL_KBD_RULE)
>+_IT_SUBST(INTLTOOL_XML_RULE)
>+_IT_SUBST(INTLTOOL_XML_NOMERGE_RULE)
>+_IT_SUBST(INTLTOOL_CAVES_RULE)
>+_IT_SUBST(INTLTOOL_SCHEMAS_RULE)
>+_IT_SUBST(INTLTOOL_THEME_RULE)
>+_IT_SUBST(INTLTOOL_SERVICE_RULE)
>+_IT_SUBST(INTLTOOL_POLICY_RULE)
>+
>+# Check the gettext tools to make sure they are GNU
>+AC_PATH_PROG(XGETTEXT, xgettext)
>+AC_PATH_PROG(MSGMERGE, msgmerge)
>+AC_PATH_PROG(MSGFMT, msgfmt)
>+AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
>+if test -z "$XGETTEXT" -o -z "$MSGMERGE" -o -z "$MSGFMT"; then
>+    AC_MSG_ERROR([GNU gettext tools not found; required for intltool])
>+fi
>+xgversion="`$XGETTEXT --version|grep '(GNU ' 2> /dev/null`"
>+mmversion="`$MSGMERGE --version|grep '(GNU ' 2> /dev/null`"
>+mfversion="`$MSGFMT --version|grep '(GNU ' 2> /dev/null`"
>+if test -z "$xgversion" -o -z "$mmversion" -o -z "$mfversion"; then
>+    AC_MSG_ERROR([GNU gettext tools not found; required for intltool])
>+fi
>+
>+AC_PATH_PROG(INTLTOOL_PERL, perl)
>+if test -z "$INTLTOOL_PERL"; then
>+   AC_MSG_ERROR([perl not found])
>+fi
>+AC_MSG_CHECKING([for perl >= 5.8.1])
>+$INTLTOOL_PERL -e "use 5.8.1;" > /dev/null 2>&1
>+if test $? -ne 0; then
>+   AC_MSG_ERROR([perl 5.8.1 is required for intltool])
>+else
>+   IT_PERL_VERSION="`$INTLTOOL_PERL -e \"printf '%vd', $^V\"`"
>+   AC_MSG_RESULT([$IT_PERL_VERSION])
>+fi
>+if test "x$2" != "xno-xml"; then
>+   AC_MSG_CHECKING([for XML::Parser])
>+   if `$INTLTOOL_PERL -e "require XML::Parser" 2>/dev/null`; then
>+       AC_MSG_RESULT([ok])
>+   else
>+       AC_MSG_ERROR([XML::Parser perl module is required for intltool])
>+   fi
>+fi
>+
>+# Substitute ALL_LINGUAS so we can use it in po/Makefile
>+AC_SUBST(ALL_LINGUAS)
>+
>+# Set DATADIRNAME correctly if it is not set yet
>+# (copied from glib-gettext.m4)
>+if test -z "$DATADIRNAME"; then
>+  AC_LINK_IFELSE(
>+    [AC_LANG_PROGRAM([[]],
>+                     [[extern int _nl_msg_cat_cntr;
>+                       return _nl_msg_cat_cntr]])],
>+    [DATADIRNAME=share],
>+    [case $host in
>+    *-*-solaris*)
>+    dnl On Solaris, if bind_textdomain_codeset is in libc,
>+    dnl GNU format message catalog is always supported,
>+    dnl since both are added to the libc all together.
>+    dnl Hence, we'd like to go with DATADIRNAME=share
>+    dnl in this case.
>+    AC_CHECK_FUNC(bind_textdomain_codeset,
>+      [DATADIRNAME=share], [DATADIRNAME=lib])
>+    ;;
>+    *)
>+    [DATADIRNAME=lib]
>+    ;;
>+    esac])
>+fi
>+AC_SUBST(DATADIRNAME)
>+
>+IT_PO_SUBDIR([po])
>+
>+])
>+
>+
>+# IT_PO_SUBDIR(DIRNAME)
>+# ---------------------
>+# All po subdirs have to be declared with this macro; the subdir "po" is
>+# declared by IT_PROG_INTLTOOL.
>+#
>+AC_DEFUN([IT_PO_SUBDIR],
>+[AC_PREREQ([2.53])dnl We use ac_top_srcdir inside AC_CONFIG_COMMANDS.
>+dnl
>+dnl The following CONFIG_COMMANDS should be executed at the very end
>+dnl of config.status.
>+AC_CONFIG_COMMANDS_PRE([
>+  AC_CONFIG_COMMANDS([$1/stamp-it], [
>+    if [ ! grep "^# INTLTOOL_MAKEFILE$" "$1/Makefile.in" > /dev/null ]; then
>+       AC_MSG_ERROR([$1/Makefile.in.in was not created by intltoolize.])
>+    fi
>+    rm -f "$1/stamp-it" "$1/stamp-it.tmp" "$1/POTFILES" "$1/Makefile.tmp"
>+    >"$1/stamp-it.tmp"
>+    [sed '/^#/d
>+	 s/^[[].*] *//
>+	 /^[ 	]*$/d
>+	'"s|^|	$ac_top_srcdir/|" \
>+      "$srcdir/$1/POTFILES.in" | sed '$!s/$/ \\/' >"$1/POTFILES"
>+    ]
>+    [sed '/^POTFILES =/,/[^\\]$/ {
>+		/^POTFILES =/!d
>+		r $1/POTFILES
>+	  }
>+	 ' "$1/Makefile.in" >"$1/Makefile"]
>+    rm -f "$1/Makefile.tmp"
>+    mv "$1/stamp-it.tmp" "$1/stamp-it"
>+  ])
>+])dnl
>+])
>+
>+# _IT_SUBST(VARIABLE)
>+# -------------------
>+# Abstract macro to do either _AM_SUBST_NOTMAKE or AC_SUBST
>+#
>+AC_DEFUN([_IT_SUBST],
>+[
>+AC_SUBST([$1])
>+m4_ifdef([_AM_SUBST_NOTMAKE], [_AM_SUBST_NOTMAKE([$1])])
>+]
>+)
>+
>+# deprecated macros
>+AU_ALIAS([AC_PROG_INTLTOOL], [IT_PROG_INTLTOOL])
>+# A hint is needed for aclocal from Automake <= 1.9.4:
>+# AC_DEFUN([AC_PROG_INTLTOOL], ...)
>+
>diff --git a/m4/nls.m4 b/m4/nls.m4
>new file mode 100644
>index 0000000..003704c
>--- /dev/null
>+++ b/m4/nls.m4
>@@ -0,0 +1,32 @@
>+# nls.m4 serial 5 (gettext-0.18)
>+dnl Copyright (C) 1995-2003, 2005-2006, 2008-2010 Free Software Foundation,
>+dnl Inc.
>+dnl This file is free software; the Free Software Foundation
>+dnl gives unlimited permission to copy and/or distribute it,
>+dnl with or without modifications, as long as this notice is preserved.
>+dnl
>+dnl This file can can be used in projects which are not available under
>+dnl the GNU General Public License or the GNU Library General Public
>+dnl License but which still want to provide support for the GNU gettext
>+dnl functionality.
>+dnl Please note that the actual code of the GNU gettext library is covered
>+dnl by the GNU Library General Public License, and the rest of the GNU
>+dnl gettext package package is covered by the GNU General Public License.
>+dnl They are *not* in the public domain.
>+
>+dnl Authors:
>+dnl   Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
>+dnl   Bruno Haible <haible@clisp.cons.org>, 2000-2003.
>+
>+AC_PREREQ([2.50])
>+
>+AC_DEFUN([AM_NLS],
>+[
>+  AC_MSG_CHECKING([whether NLS is requested])
>+  dnl Default is enabled NLS
>+  AC_ARG_ENABLE([nls],
>+    [  --disable-nls           do not use Native Language Support],
>+    USE_NLS=$enableval, USE_NLS=yes)
>+  AC_MSG_RESULT([$USE_NLS])
>+  AC_SUBST([USE_NLS])
>+])
>diff --git a/m4/pkg.m4 b/m4/pkg.m4
>new file mode 100644
>index 0000000..f26f84c
>--- /dev/null
>+++ b/m4/pkg.m4
>@@ -0,0 +1,199 @@
>+# pkg.m4 - Macros to locate and utilise pkg-config.            -*- Autoconf -*-
>+# serial 1 (pkg-config-0.24)
>+# 
>+# Copyright Â© 2004 Scott James Remnant <scott@netsplit.com>.
>+#
>+# This program is free software; you can redistribute it and/or modify
>+# it under the terms of the GNU General Public License as published by
>+# the Free Software Foundation; either version 2 of the License, or
>+# (at your option) any later version.
>+#
>+# This program is distributed in the hope that it will be useful, but
>+# WITHOUT ANY WARRANTY; without even the implied warranty of
>+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
>+# General Public License for more details.
>+#
>+# You should have received a copy of the GNU General Public License
>+# along with this program; if not, write to the Free Software
>+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
>+#
>+# As a special exception to the GNU General Public License, if you
>+# distribute this file as part of a program that contains a
>+# configuration script generated by Autoconf, you may include it under
>+# the same distribution terms that you use for the rest of that program.
>+
>+# PKG_PROG_PKG_CONFIG([MIN-VERSION])
>+# ----------------------------------
>+AC_DEFUN([PKG_PROG_PKG_CONFIG],
>+[m4_pattern_forbid([^_?PKG_[A-Z_]+$])
>+m4_pattern_allow([^PKG_CONFIG(_(PATH|LIBDIR|SYSROOT_DIR|ALLOW_SYSTEM_(CFLAGS|LIBS)))?$])
>+m4_pattern_allow([^PKG_CONFIG_(DISABLE_UNINSTALLED|TOP_BUILD_DIR|DEBUG_SPEW)$])
>+AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])
>+AC_ARG_VAR([PKG_CONFIG_PATH], [directories to add to pkg-config's search path])
>+AC_ARG_VAR([PKG_CONFIG_LIBDIR], [path overriding pkg-config's built-in search path])
>+
>+if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
>+	AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
>+fi
>+if test -n "$PKG_CONFIG"; then
>+	_pkg_min_version=m4_default([$1], [0.9.0])
>+	AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
>+	if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
>+		AC_MSG_RESULT([yes])
>+	else
>+		AC_MSG_RESULT([no])
>+		PKG_CONFIG=""
>+	fi
>+fi[]dnl
>+])# PKG_PROG_PKG_CONFIG
>+
>+# PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
>+#
>+# Check to see whether a particular set of modules exists.  Similar
>+# to PKG_CHECK_MODULES(), but does not set variables or print errors.
>+#
>+# Please remember that m4 expands AC_REQUIRE([PKG_PROG_PKG_CONFIG])
>+# only at the first occurence in configure.ac, so if the first place
>+# it's called might be skipped (such as if it is within an "if", you
>+# have to call PKG_CHECK_EXISTS manually
>+# --------------------------------------------------------------
>+AC_DEFUN([PKG_CHECK_EXISTS],
>+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
>+if test -n "$PKG_CONFIG" && \
>+    AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
>+  m4_default([$2], [:])
>+m4_ifvaln([$3], [else
>+  $3])dnl
>+fi])
>+
>+# _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
>+# ---------------------------------------------
>+m4_define([_PKG_CONFIG],
>+[if test -n "$$1"; then
>+    pkg_cv_[]$1="$$1"
>+ elif test -n "$PKG_CONFIG"; then
>+    PKG_CHECK_EXISTS([$3],
>+                     [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`
>+		      test "x$?" != "x0" && pkg_failed=yes ],
>+		     [pkg_failed=yes])
>+ else
>+    pkg_failed=untried
>+fi[]dnl
>+])# _PKG_CONFIG
>+
>+# _PKG_SHORT_ERRORS_SUPPORTED
>+# -----------------------------
>+AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
>+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])
>+if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
>+        _pkg_short_errors_supported=yes
>+else
>+        _pkg_short_errors_supported=no
>+fi[]dnl
>+])# _PKG_SHORT_ERRORS_SUPPORTED
>+
>+
>+# PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
>+# [ACTION-IF-NOT-FOUND])
>+#
>+#
>+# Note that if there is a possibility the first call to
>+# PKG_CHECK_MODULES might not happen, you should be sure to include an
>+# explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
>+#
>+#
>+# --------------------------------------------------------------
>+AC_DEFUN([PKG_CHECK_MODULES],
>+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
>+AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
>+AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
>+
>+pkg_failed=no
>+AC_MSG_CHECKING([for $1])
>+
>+_PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
>+_PKG_CONFIG([$1][_LIBS], [libs], [$2])
>+
>+m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
>+and $1[]_LIBS to avoid the need to call pkg-config.
>+See the pkg-config man page for more details.])
>+
>+if test $pkg_failed = yes; then
>+   	AC_MSG_RESULT([no])
>+        _PKG_SHORT_ERRORS_SUPPORTED
>+        if test $_pkg_short_errors_supported = yes; then
>+	        $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --print-errors --cflags --libs "$2" 2>&1`
>+        else 
>+	        $1[]_PKG_ERRORS=`$PKG_CONFIG --print-errors --cflags --libs "$2" 2>&1`
>+        fi
>+	# Put the nasty error message in config.log where it belongs
>+	echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
>+
>+	m4_default([$4], [AC_MSG_ERROR(
>+[Package requirements ($2) were not met:
>+
>+$$1_PKG_ERRORS
>+
>+Consider adjusting the PKG_CONFIG_PATH environment variable if you
>+installed software in a non-standard prefix.
>+
>+_PKG_TEXT])[]dnl
>+        ])
>+elif test $pkg_failed = untried; then
>+     	AC_MSG_RESULT([no])
>+	m4_default([$4], [AC_MSG_FAILURE(
>+[The pkg-config script could not be found or is too old.  Make sure it
>+is in your PATH or set the PKG_CONFIG environment variable to the full
>+path to pkg-config.
>+
>+_PKG_TEXT
>+
>+To get pkg-config, see <http://pkg-config.freedesktop.org/>.])[]dnl
>+        ])
>+else
>+	$1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
>+	$1[]_LIBS=$pkg_cv_[]$1[]_LIBS
>+        AC_MSG_RESULT([yes])
>+	$3
>+fi[]dnl
>+])# PKG_CHECK_MODULES
>+
>+
>+# PKG_INSTALLDIR(DIRECTORY)
>+# -------------------------
>+# Substitutes the variable pkgconfigdir as the location where a module
>+# should install pkg-config .pc files. By default the directory is
>+# $libdir/pkgconfig, but the default can be changed by passing
>+# DIRECTORY. The user can override through the --with-pkgconfigdir
>+# parameter.
>+AC_DEFUN([PKG_INSTALLDIR],
>+[m4_pushdef([pkg_default], [m4_default([$1], ['${libdir}/pkgconfig'])])
>+m4_pushdef([pkg_description],
>+    [pkg-config installation directory @<:@]pkg_default[@:>@])
>+AC_ARG_WITH([pkgconfigdir],
>+    [AS_HELP_STRING([--with-pkgconfigdir], pkg_description)],,
>+    [with_pkgconfigdir=]pkg_default)
>+AC_SUBST([pkgconfigdir], [$with_pkgconfigdir])
>+m4_popdef([pkg_default])
>+m4_popdef([pkg_description])
>+]) dnl PKG_INSTALLDIR
>+
>+
>+# PKG_NOARCH_INSTALLDIR(DIRECTORY)
>+# -------------------------
>+# Substitutes the variable noarch_pkgconfigdir as the location where a
>+# module should install arch-independent pkg-config .pc files. By
>+# default the directory is $datadir/pkgconfig, but the default can be
>+# changed by passing DIRECTORY. The user can override through the
>+# --with-noarch-pkgconfigdir parameter.
>+AC_DEFUN([PKG_NOARCH_INSTALLDIR],
>+[m4_pushdef([pkg_default], [m4_default([$1], ['${datadir}/pkgconfig'])])
>+m4_pushdef([pkg_description],
>+    [pkg-config arch-independent installation directory @<:@]pkg_default[@:>@])
>+AC_ARG_WITH([noarch-pkgconfigdir],
>+    [AS_HELP_STRING([--with-noarch-pkgconfigdir], pkg_description)],,
>+    [with_noarch_pkgconfigdir=]pkg_default)
>+AC_SUBST([noarch_pkgconfigdir], [$with_noarch_pkgconfigdir])
>+m4_popdef([pkg_default])
>+m4_popdef([pkg_description])
>+]) dnl PKG_NOARCH_INSTALLDIR
>-- 
>1.7.1
>

Actions: View | Splinter Review

Attachments on bug 61334: 75397 | 75398 | 75399

Use of freedesktop.org services, including Bugzilla, is subject to our Code of Conduct. How we collect and use information is described in our Privacy Policy.