Attachment 83774 Details for Bug 67858 – Add vapigen support

[patch] Add vapigen support

0005-build-Add-vapigen-support.patch (text/plain), 5.21 KB, created by Philip Withnall on 2013-08-07 09:34:17 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Philip Withnall

Created: 2013-08-07 09:34:17 UTC

Size: 5.21 KB

patch

obsolete

>From 8dd13d13b07462ea9b8d8187467b4e5c2d2db6bd Mon Sep 17 00:00:00 2001
>From: Philip Withnall <philip@tecnocode.co.uk>
>Date: Wed, 7 Aug 2013 11:23:23 +0200
>Subject: [PATCH 5/6] build: Add vapigen support
>MIME-Version: 1.0
>Content-Type: text/plain; charset=UTF-8
>Content-Transfer-Encoding: 8bit
>
>This generates geoclue-2.0.vapi. The bindings havenât been tested,
>so some introspection annotations might need fixing.
>---
> configure.ac    |   1 +
> m4/vapigen.m4   | 101 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
> src/Makefile.am |  23 +++++++++++++
> 3 files changed, 125 insertions(+)
> create mode 100644 m4/vapigen.m4
>
>diff --git a/configure.ac b/configure.ac
>index 825132c..acb884f 100644
>--- a/configure.ac
>+++ b/configure.ac
>@@ -94,6 +94,7 @@ else
> fi
> 
> GOBJECT_INTROSPECTION_CHECK([0.6.2])
>+VAPIGEN_CHECK()
> 
> AC_CONFIG_FILES([
>   Makefile
>diff --git a/m4/vapigen.m4 b/m4/vapigen.m4
>new file mode 100644
>index 0000000..2c435e7
>--- /dev/null
>+++ b/m4/vapigen.m4
>@@ -0,0 +1,101 @@
>+dnl vapigen.m4
>+dnl
>+dnl Copyright 2012 Evan Nemerson
>+dnl
>+dnl This library is free software; you can redistribute it and/or
>+dnl modify it under the terms of the GNU Lesser General Public
>+dnl License as published by the Free Software Foundation; either
>+dnl version 2.1 of the License, or (at your option) any later version.
>+dnl
>+dnl This library is distributed in the hope that it will be useful,
>+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
>+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
>+dnl Lesser General Public License for more details.
>+dnl
>+dnl You should have received a copy of the GNU Lesser General Public
>+dnl License along with this library; if not, write to the Free Software
>+dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
>+
>+# VAPIGEN_CHECK([VERSION], [API_VERSION], [FOUND_INTROSPECTION], [DEFAULT])
>+# --------------------------------------
>+# Check vapigen existence and version
>+#
>+# See http://live.gnome.org/Vala/UpstreamGuide for detailed documentation
>+AC_DEFUN([VAPIGEN_CHECK],
>+[
>+  AS_IF([test "x$3" != "xyes"], [
>+      m4_provide_if([GOBJECT_INTROSPECTION_CHECK], [], [
>+          m4_provide_if([GOBJECT_INTROSPECTION_REQUIRE], [], [
>+              AC_MSG_ERROR([[You must call GOBJECT_INTROSPECTION_CHECK or GOBJECT_INTROSPECTION_REQUIRE before using VAPIGEN_CHECK unless using the FOUND_INTROSPECTION argument is "yes"]])
>+            ])
>+        ])
>+    ])
>+
>+  AC_ARG_ENABLE([vala],
>+    [AS_HELP_STRING([--enable-vala[=@<:@no/auto/yes@:>@]],[build Vala bindings @<:@default=]ifelse($4,,auto,$4)[@:>@])],,[
>+      AS_IF([test "x$4" = "x"], [
>+          enable_vala=auto
>+        ], [
>+          enable_vala=$4
>+        ])
>+    ])
>+
>+  AS_CASE([$enable_vala], [no], [enable_vala=no],
>+      [yes], [
>+        AS_IF([test "x$3" != "xyes" -a "x$found_introspection" != "xyes"], [
>+            AC_MSG_ERROR([Vala bindings require GObject Introspection])
>+          ])
>+      ], [auto], [
>+        AS_IF([test "x$3" != "xyes" -a "x$found_introspection" != "xyes"], [
>+            enable_vala=no
>+          ])
>+      ], [
>+        AC_MSG_ERROR([Invalid argument passed to --enable-vala, should be one of @<:@no/auto/yes@:>@])
>+      ])
>+
>+  AS_IF([test "x$2" = "x"], [
>+      vapigen_pkg_name=vapigen
>+    ], [
>+      vapigen_pkg_name=vapigen-$2
>+    ])
>+  AS_IF([test "x$1" = "x"], [
>+      vapigen_pkg="$vapigen_pkg_name"
>+    ], [
>+      vapigen_pkg="$vapigen_pkg_name >= $1"
>+    ])
>+
>+  PKG_PROG_PKG_CONFIG
>+
>+  PKG_CHECK_EXISTS([$vapigen_pkg], [
>+      AS_IF([test "$enable_vala" = "auto"], [
>+          enable_vala=yes
>+        ])
>+    ], [
>+      AS_CASE([$enable_vala], [yes], [
>+          AC_MSG_ERROR([$vapigen_pkg not found])
>+        ], [auto], [
>+          enable_vala=no
>+        ])
>+    ])
>+
>+  AC_MSG_CHECKING([for vapigen])
>+
>+  AS_CASE([$enable_vala],
>+    [yes], [
>+      VAPIGEN=`$PKG_CONFIG --variable=vapigen $vapigen_pkg_name`
>+      VAPIGEN_MAKEFILE=`$PKG_CONFIG --variable=datadir $vapigen_pkg_name`/vala/Makefile.vapigen
>+      AS_IF([test "x$2" = "x"], [
>+          VAPIGEN_VAPIDIR=`$PKG_CONFIG --variable=vapidir $vapigen_pkg_name`
>+        ], [
>+          VAPIGEN_VAPIDIR=`$PKG_CONFIG --variable=vapidir_versioned $vapigen_pkg_name`
>+        ])
>+    ])
>+
>+  AC_MSG_RESULT([$enable_vala])
>+
>+  AC_SUBST([VAPIGEN])
>+  AC_SUBST([VAPIGEN_VAPIDIR])
>+  AC_SUBST([VAPIGEN_MAKEFILE])
>+
>+  AM_CONDITIONAL(ENABLE_VAPIGEN, test "x$enable_vala" = "xyes")
>+])
>diff --git a/src/Makefile.am b/src/Makefile.am
>index 6a2bb33..908172a 100644
>--- a/src/Makefile.am
>+++ b/src/Makefile.am
>@@ -80,6 +80,29 @@ typelib_DATA = $(INTROSPECTION_GIRS:.gir=.typelib)
> 
> CLEANFILES += $(gir_DATA) $(typelib_DATA)
> 
>+# vapigen
>+if ENABLE_VAPIGEN
>+-include $(VAPIGEN_MAKEFILE)
>+
>+# Note: The VAPI file name has to match the pkg-config file name.
>+geoclue-2.0.vapi: Geoclue-1.0.gir
>+
>+VAPIGEN_VAPIS = geoclue-2.0.vapi
>+
>+geoclue_2_0_vapi_DEPS = gio-2.0
>+geoclue_2_0_vapi_FILES = Geoclue-1.0.gir
>+
>+geoclue-2.0.deps:
>+	$(AM_V_GEN) for pkg in $(geoclue_2_0_vapi_DEPS); do \
>+		echo $$pkg >> $@; \
>+	done
>+
>+vapidir = $(datadir)/vala/vapi
>+vapi_DATA = $(VAPIGEN_VAPIS) $(VAPIGEN_VAPIS:.vapi=.deps)
>+
>+CLEANFILES += $(vapi_DATA)
>+
>+endif # ENABLE_VAPIGEN
> endif # HAVE_INTROSPECTION
> 
> -include $(top_srcdir)/git.mk
>-- 
>1.8.3.1
>

Actions: View | Splinter Review

Attachments on bug 67858: 83770 | 83771 | 83772 | 83773 | 83774 | 83775 | 90203 | 90204 | 90205

Use of freedesktop.org services, including Bugzilla, is subject to our Code of Conduct. How we collect and use information is described in our Privacy Policy.