I've seen issues like this many times and the issue is almost always that they have some input or output to a shader that doesn't have an explicit location specified.  Could you please double-check all the shaders for that.

The fragement shader is converted to spir-v IR through glslangValidator tool

# glslangValidator -V -H -o Smoke.frag.spv Smoke.frag

The Smoke.frag.spv is correct and can be disassembled as

# spirv-dis Smoke.frag.spv

; SPIR-V
; Version: 1.0
; Generator: Khronos Glslang Reference Front End; 1
; Bound: 19
; Schema: 0
               OpCapability Shader
          %1 = OpExtInstImport "GLSL.std.450"
               OpMemoryModel Logical GLSL450
               OpEntryPoint Fragment %main "main" %fragcolor %color
               OpExecutionMode %main OriginUpperLeft
               OpSource ESSL 310
               OpName %main "main"
               OpName %fragcolor "fragcolor"
               OpName %color "color"
               OpDecorate %fragcolor Location 0
       %void = OpTypeVoid
          %3 = OpTypeFunction %void
      %float = OpTypeFloat 32
    %v4float = OpTypeVector %float 4
%_ptr_Output_v4float = OpTypePointer Output %v4float
  %fragcolor = OpVariable %_ptr_Output_v4float Output
    %v3float = OpTypeVector %float 3
%_ptr_Input_v3float = OpTypePointer Input %v3float
      %color = OpVariable %_ptr_Input_v3float Input
  %float_0_5 = OpConstant %float 0.5
       %main = OpFunction %void None %3
          %5 = OpLabel
         %13 = OpLoad %v3float %color
         %15 = OpCompositeExtract %float %13 0
         %16 = OpCompositeExtract %float %13 1
         %17 = OpCompositeExtract %float %13 2
         %18 = OpCompositeConstruct %v4float %15 %16 %17 %float_0_5
               OpStore %fragcolor %18
               OpReturn
               OpFunctionEnd

As I suspected the %color input variable isn't decorated with a location.  If you edit the GLSL for both fragment and vertex shaders to make sure it had a location on both sides of the interface, that should fix it.

As a side-note, one of these days we should add an assert to the SPIR-V -> NIR pass that gives a nice descriptive name if someone has an input or output variable without a location.

(In reply to Jason Ekstrand from comment #3)
> As I suspected the %color input variable isn't decorated with a location. 
> If you edit the GLSL for both fragment and vertex shaders to make sure it
> had a location on both sides of the interface, that should fix it.

Thanks Jason

The issue can be fixed by adding layout(location = 0) to input variable "color". We may need emphasize it in spec, i.e. the attribute location should be set explicitly. It's a little confusing, as the game developer may assume it's set to 0 implicitly.

diff --git a/LunarGSamples/demos/smoke/Smoke.frag b/LunarGSamples/demos/smoke/Smoke.frag
index e07a46f..82bee59 100644
--- a/LunarGSamples/demos/smoke/Smoke.frag
+++ b/LunarGSamples/demos/smoke/Smoke.frag
@@ -2,7 +2,7 @@
 
 precision highp float;
 
-in vec3 color;
+layout(location = 0) in vec3 color;
 
 layout(location = 0) out vec4 fragcolor;

I've filed a bug against GLSLang asking them to error out in this case.  That should solve 90% of the user error here.

https://github.com/KhronosGroup/glslang/issues/781